Poky Project Discussions
 help / color / mirror / Atom feed
* [PATCH 0/5] docbook-utils and friends
@ 2011-02-16  4:32 Scott Garman
  2011-02-16  4:32 ` [PATCH 1/5] texinfo: recipe cleanup, add native support Scott Garman
                   ` (5 more replies)
  0 siblings, 6 replies; 7+ messages in thread
From: Scott Garman @ 2011-02-16  4:32 UTC (permalink / raw)
  To: poky

From: Scott Garman <scott.a.garman@intel.com>

Hi Saul,

This pull request includes documentation-related dependencies
and fixes so that the iputils recipe (and most likely many others)
can build its documentation correctly.

I tested it on qemux86 and qemumips, and on a stripped-down
openSUSE 11.2 chroot where I even removed documentation-related
host utilities that we list in our quick start guide.

Pull URL: git://git.pokylinux.org/poky-contrib.git
  Branch: sgarman/docbook-fixes-final
  Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=sgarman/docbook-fixes-final

Thanks,
    Scott Garman <scott.a.garman@intel.com>
---


Scott Garman (5):
  texinfo: recipe cleanup, add native support
  sgml-common-native: fix license info and checksum fields
  docbook-utils-native: new recipe v0.6.14
  opensp: improve configuration and install steps
  iputils: enable generation of man pages

 .../docbook-utils/docbook-utils-native_0.6.14.bb   |   48 ++++++++++++++++++++
 meta/recipes-devtools/opensp/opensp_1.5.bb         |   18 +++++++
 .../sgml-common/sgml-common-native_0.6.3.bb        |   10 ++---
 meta/recipes-extended/iputils/iputils_s20101006.bb |   13 ++---
 meta/recipes-extended/texinfo/texinfo_4.13a.bb     |   26 ++++++-----
 5 files changed, 90 insertions(+), 25 deletions(-)
 create mode 100644 meta/recipes-devtools/docbook-utils/docbook-utils-native_0.6.14.bb



^ permalink raw reply	[flat|nested] 7+ messages in thread

* [PATCH 1/5] texinfo: recipe cleanup, add native support
  2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
@ 2011-02-16  4:32 ` Scott Garman
  2011-02-16  4:33 ` [PATCH 2/5] sgml-common-native: fix license info and checksum fields Scott Garman
                   ` (4 subsequent siblings)
  5 siblings, 0 replies; 7+ messages in thread
From: Scott Garman @ 2011-02-16  4:32 UTC (permalink / raw)
  To: poky

From: Scott Garman <scott.a.garman@intel.com>

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-extended/texinfo/texinfo_4.13a.bb |   26 +++++++++++++----------
 1 files changed, 15 insertions(+), 11 deletions(-)

diff --git a/meta/recipes-extended/texinfo/texinfo_4.13a.bb b/meta/recipes-extended/texinfo/texinfo_4.13a.bb
index be10c26..ac89b66 100644
--- a/meta/recipes-extended/texinfo/texinfo_4.13a.bb
+++ b/meta/recipes-extended/texinfo/texinfo_4.13a.bb
@@ -1,29 +1,31 @@
-DESCRIPTION = "Texinfo is a documentation system that can produce both online \
-information and printed output from a single source file. The GNU \
-Project uses the Texinfo file format for most of its documentation."
-
-SECTION = "console/utils"
+SUMMARY = "Documentation system for on-line information and printed output"
+DESCRIPTION = "Texinfo is a documentation system that can produce both \
+online information and printed output from a single source file. The \
+GNU Project uses the Texinfo file format for most of its documentation."
 HOMEPAGE = "http://www.gnu.org/software/texinfo/"
+SECTION = "console/utils"
 PRIORITY = "required"
-LICENSE = "GPLV3+"
-PR = "r0"
-
+LICENSE = "GPLv3+"
 LIC_FILES_CHKSUM = "file://COPYING;md5=adefda309052235aa5d1e99ce7557010"
+PR = "r0"
 
-DEPENDS  = "zlib"
+DEPENDS = "zlib"
 
-SRC_URI = "http://ftp.gnu.org/gnu/texinfo/texinfo-${PV}.tar.gz \
+SRC_URI = "${GNU_MIRROR}/texinfo/texinfo-${PV}.tar.gz \
            file://texinfo-4.12-zlib.patch;striplevel=1 \
            file://texinfo-4.13a-data_types.patch;striplevel=1 \
            file://texinfo-4.13a-mosdo-crash.patch;striplevel=1 \
            file://texinfo-4.13a-powerpc.patch;striplevel=1 \
            file://texinfo-4.13a-help-index-segfault.patch;striplevel=1"
 
-inherit gettext autotools
+SRC_URI[md5sum] = "71ba711519209b5fb583fed2b3d86fcb"
+SRC_URI[sha256sum] = "1303e91a1c752b69a32666a407e9fbdd6e936def4b09bc7de30f416301530d68"
 
 S = ${WORKDIR}/texinfo-4.13
 tex_texinfo = "texmf/tex/texinfo"
 
+inherit gettext autotools
+
 do_configure() {
 	oe_runconf
 }
@@ -55,3 +57,5 @@ FILES_${PN}-doc = "${datadir}/texinfo ${infodir}/texinfo* \
                    ${mandir}/man1/texindex.1* ${mandir}/man1/texi2dvi.1* \
                    ${mandir}/man1/texi2pdf.1* ${mandir}/man1/pdftexi2dvi.1*"
 FILES_${PN}-dbg = "${bindir}/.debug/texindex ${bindir}/.debug/makeinfo"
+
+BBCLASSEXTEND = "native"
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 7+ messages in thread

* [PATCH 2/5] sgml-common-native: fix license info and checksum fields
  2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
  2011-02-16  4:32 ` [PATCH 1/5] texinfo: recipe cleanup, add native support Scott Garman
@ 2011-02-16  4:33 ` Scott Garman
  2011-02-16  4:33 ` [PATCH 3/5] docbook-utils-native: new recipe v0.6.14 Scott Garman
                   ` (3 subsequent siblings)
  5 siblings, 0 replies; 7+ messages in thread
From: Scott Garman @ 2011-02-16  4:33 UTC (permalink / raw)
  To: poky

From: Scott Garman <scott.a.garman@intel.com>

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 .../sgml-common/sgml-common-native_0.6.3.bb        |   10 ++++------
 1 files changed, 4 insertions(+), 6 deletions(-)

diff --git a/meta/recipes-devtools/sgml-common/sgml-common-native_0.6.3.bb b/meta/recipes-devtools/sgml-common/sgml-common-native_0.6.3.bb
index 7e9b923..2c8d874 100644
--- a/meta/recipes-devtools/sgml-common/sgml-common-native_0.6.3.bb
+++ b/meta/recipes-devtools/sgml-common/sgml-common-native_0.6.3.bb
@@ -7,12 +7,10 @@ add entries to (or remove entries from) centralized catalogs \
 whose entries are pointers to SGML open catalogs, \
 as defined by OASIS."
 HOMEPAGE = "http://sources.redhat.com/docbook-tools/"
-LICENSE = "GPLv2"
-# The COPYING file sgml-common ships with is just a symlink to
-# /usr/share/automake/COPYING, which means we can't verify it
-# using our normal means. :( Hash the README file instead as
-# LIC_FILES_CHKSUM is still required.
-LIC_FILES_CHKSUM = "file://README;md5=197bd940bf13548ac2198e4f77d3da92"
+LICENSE = "GPLv2+"
+# See the comments in license.patch when upgrading this recipe.
+# This is inteded to be a temporary workaround.
+LIC_FILES_CHKSUM = "file://LICENSE-GPLv2;md5=ab8a50abe86dfc859e148baae043c89b"
 SECTION = "base"
 
 PR = "r0"
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 7+ messages in thread

* [PATCH 3/5] docbook-utils-native: new recipe v0.6.14
  2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
  2011-02-16  4:32 ` [PATCH 1/5] texinfo: recipe cleanup, add native support Scott Garman
  2011-02-16  4:33 ` [PATCH 2/5] sgml-common-native: fix license info and checksum fields Scott Garman
@ 2011-02-16  4:33 ` Scott Garman
  2011-02-16  4:33 ` [PATCH 4/5] opensp: improve configuration and install steps Scott Garman
                   ` (2 subsequent siblings)
  5 siblings, 0 replies; 7+ messages in thread
From: Scott Garman @ 2011-02-16  4:33 UTC (permalink / raw)
  To: poky

From: Scott Garman <scott.a.garman@intel.com>

Recipe derived from OpenEmbedded. Starting with a -native only
version for now.

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 .../docbook-utils/docbook-utils-native_0.6.14.bb   |   48 ++++++++++++++++++++
 1 files changed, 48 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-devtools/docbook-utils/docbook-utils-native_0.6.14.bb

diff --git a/meta/recipes-devtools/docbook-utils/docbook-utils-native_0.6.14.bb b/meta/recipes-devtools/docbook-utils/docbook-utils-native_0.6.14.bb
new file mode 100644
index 0000000..2263c0a
--- /dev/null
+++ b/meta/recipes-devtools/docbook-utils/docbook-utils-native_0.6.14.bb
@@ -0,0 +1,48 @@
+SUMMARY = "Utilities for formatting and manipulating DocBook documents"
+DESCRIPTION = "A collection of all the free software tools you need to \
+work on and format DocBook documents."
+HOMEPAGE = "http://sources.redhat.com/docbook-tools/"
+SECTION = "console/utils"
+PRIORITY = "required"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+DEPENDS = "openjade-native sgmlspl-native docbook-dsssl-stylesheets-native docbook-sgml-dtd-3.1-native"
+
+PR = "r0"
+
+SRC_URI = "ftp://sources.redhat.com/pub/docbook-tools/new-trials/SOURCES/docbook-utils-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "6b41b18c365c01f225bc417cf632d81c"
+SRC_URI[sha256sum] = "48faab8ee8a7605c9342fb7b906e0815e3cee84a489182af38e8f7c0df2e92e9"
+
+inherit autotools native
+
+do_configure_prepend() {
+	# Fix hard-coded references to /etc/sgml
+	sed -i -e "s|/etc/sgml|${sysconfdir}/sgml|g" bin/jw.in
+	sed -i -e "s|/etc/sgml|${sysconfdir}/sgml|g" doc/man/Makefile.am
+	sed -i -e "s|/etc/sgml|${sysconfdir}/sgml|g" doc/HTML/Makefile.am
+}
+
+do_install() {
+	install -d ${D}${bindir}
+	# Install the binaries and a bunch of other commonly used names for them.
+	for doctype in html ps dvi man pdf rtf tex texi txt
+	do
+		install -m 0755 ${S}/bin/docbook2$doctype ${D}${bindir}/
+		ln -sf docbook2x-$doctype ${D}${bindir}/db2$doctype
+		ln -sf docbook2$doctype ${D}${bindir}/db2$doctype
+		ln -sf docbook2$doctype ${D}${bindir}/docbook-to-$doctype
+	done
+
+	install -m 0755 ${S}/bin/jw ${D}${bindir}/
+	for i in backends/dvi backends/html backends/man \
+		backends/pdf backends/ps backends/rtf backends/tex \
+		backends/texi backends/txt frontends/docbook \
+		helpers/docbook2man-spec.pl helpers/docbook2texi-spec.pl \
+		docbook-utils.dsl
+	do
+		install -d ${D}${datadir}/sgml/docbook/utils-${PV}/`dirname $i`
+		install ${S}/$i ${D}${datadir}/sgml/docbook/utils-${PV}/$i
+	done
+}
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 7+ messages in thread

* [PATCH 4/5] opensp: improve configuration and install steps
  2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
                   ` (2 preceding siblings ...)
  2011-02-16  4:33 ` [PATCH 3/5] docbook-utils-native: new recipe v0.6.14 Scott Garman
@ 2011-02-16  4:33 ` Scott Garman
  2011-02-16  4:33 ` [PATCH 5/5] iputils: enable generation of man pages Scott Garman
  2011-02-22 15:49 ` [PATCH 0/5] docbook-utils and friends Saul Wold
  5 siblings, 0 replies; 7+ messages in thread
From: Scott Garman @ 2011-02-16  4:33 UTC (permalink / raw)
  To: poky

From: Scott Garman <scott.a.garman@intel.com>

* For the -native case we need to point two configure
  options to the SGML catalogs in the native sysroot
* Some packages (e.g, iputils) use different names for
  the openSP utilities, so create these names as
  symlinks after do_install

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-devtools/opensp/opensp_1.5.bb |   18 ++++++++++++++++++
 1 files changed, 18 insertions(+), 0 deletions(-)

diff --git a/meta/recipes-devtools/opensp/opensp_1.5.bb b/meta/recipes-devtools/opensp/opensp_1.5.bb
index bda87cb..61022e0 100644
--- a/meta/recipes-devtools/opensp/opensp_1.5.bb
+++ b/meta/recipes-devtools/opensp/opensp_1.5.bb
@@ -24,4 +24,22 @@ S = "${WORKDIR}/OpenSP-${PV}"
 
 inherit autotools gettext
 
+EXTRA_OECONF_virtclass-native = "\
+	--enable-default-catalog=${sysconfdir}/sgml/catalog \
+	--enable-default-search-path=${datadir}/sgml \
+	"
+
+do_install_append() {
+	# Set up symlinks to often-used alternate names. See
+	# http://www.linuxfromscratch.org/blfs/view/stable/pst/opensp.html
+	cd ${D}${libdir}
+	ln -sf libosp.so libsp.so
+
+	cd ${D}${bindir}
+	for util in nsgmls sgmlnorm spam spcat spent sx; do
+		ln -sf o$util $util	
+	done
+	ln -sf osx sgml2xml
+}
+
 BBCLASSEXTEND = "native"
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 7+ messages in thread

* [PATCH 5/5] iputils: enable generation of man pages
  2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
                   ` (3 preceding siblings ...)
  2011-02-16  4:33 ` [PATCH 4/5] opensp: improve configuration and install steps Scott Garman
@ 2011-02-16  4:33 ` Scott Garman
  2011-02-22 15:49 ` [PATCH 0/5] docbook-utils and friends Saul Wold
  5 siblings, 0 replies; 7+ messages in thread
From: Scott Garman @ 2011-02-16  4:33 UTC (permalink / raw)
  To: poky

From: Scott Garman <scott.a.garman@intel.com>

This fixes [BUGID #211]

Signed-off-by: Scott Garman <scott.a.garman@intel.com>
---
 meta/recipes-extended/iputils/iputils_s20101006.bb |   13 +++++--------
 1 files changed, 5 insertions(+), 8 deletions(-)

diff --git a/meta/recipes-extended/iputils/iputils_s20101006.bb b/meta/recipes-extended/iputils/iputils_s20101006.bb
index 0a42017..c4db5b4 100644
--- a/meta/recipes-extended/iputils/iputils_s20101006.bb
+++ b/meta/recipes-extended/iputils/iputils_s20101006.bb
@@ -11,7 +11,7 @@ LIC_FILES_CHKSUM = "file://ping.c;beginline=1;endline=35;md5=f9ceb201733e9a6cf8f
                     file://arping.c;beginline=1;endline=10;md5=ada2a6d06acc90f943bddf40d15e0541 \
                     file://tftpd.c;beginline=1;endline=32;md5=28834bf8a91a5b8a92755dbee709ef96 "
 
-DEPENDS = "sysfsutils openssl"
+DEPENDS = "sysfsutils openssl docbook-utils-native"
 
 PR = "r0"
 
@@ -26,11 +26,8 @@ SRC_URI = "http://www.skbuff.net/iputils/${PN}-${PV}.tar.bz2 \
 SRC_URI[md5sum] = "a36c25e9ec17e48be514dc0485e7376c"
 SRC_URI[sha256sum] = "fd3af46c80ebb99607c2ca1f2a3608b6fe828e25bbec6e54f2afd25f6ddb6ee7"
 
-# man is not compiled here, since it requires docbook-utils-native
-# which is not available in poky
-
 do_compile () {
-	oe_runmake 'CC=${CC} -D_GNU_SOURCE' VPATH="${STAGING_LIBDIR}" all
+	oe_runmake 'CC=${CC} -D_GNU_SOURCE' VPATH="${STAGING_LIBDIR}" all man
 }
 
 do_install () {
@@ -44,9 +41,9 @@ do_install () {
 	  install -m 0755 $i ${D}${base_bindir}/
 	done
 	# Manual pages for things we build packages for
-#	for i in tracepath.8 traceroute6.8 ping.8 arping.8; do
-#	  install -m 0644 doc/$i ${D}${mandir}/man8/ || true
-#	done
+	for i in tracepath.8 traceroute6.8 ping.8 arping.8; do
+	  install -m 0644 doc/$i ${D}${mandir}/man8/ || true
+	done
 }
 
 # Busybox also provides ping and ping6, so use update-alternatives
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 7+ messages in thread

* Re: [PATCH 0/5] docbook-utils and friends
  2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
                   ` (4 preceding siblings ...)
  2011-02-16  4:33 ` [PATCH 5/5] iputils: enable generation of man pages Scott Garman
@ 2011-02-22 15:49 ` Saul Wold
  5 siblings, 0 replies; 7+ messages in thread
From: Saul Wold @ 2011-02-22 15:49 UTC (permalink / raw)
  To: Scott Garman; +Cc: poky

On 02/15/2011 08:32 PM, Scott Garman wrote:
> From: Scott Garman<scott.a.garman@intel.com>
>
> Hi Saul,
>
> This pull request includes documentation-related dependencies
> and fixes so that the iputils recipe (and most likely many others)
> can build its documentation correctly.
>
> I tested it on qemux86 and qemumips, and on a stripped-down
> openSUSE 11.2 chroot where I even removed documentation-related
> host utilities that we list in our quick start guide.
>
> Pull URL: git://git.pokylinux.org/poky-contrib.git
>    Branch: sgarman/docbook-fixes-final
>    Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=sgarman/docbook-fixes-final
>
> Thanks,
>      Scott Garman<scott.a.garman@intel.com>
> ---
>
>
> Scott Garman (5):
>    texinfo: recipe cleanup, add native support
>    sgml-common-native: fix license info and checksum fields
>    docbook-utils-native: new recipe v0.6.14
>    opensp: improve configuration and install steps
>    iputils: enable generation of man pages
>
>   .../docbook-utils/docbook-utils-native_0.6.14.bb   |   48 ++++++++++++++++++++
>   meta/recipes-devtools/opensp/opensp_1.5.bb         |   18 +++++++
>   .../sgml-common/sgml-common-native_0.6.3.bb        |   10 ++---
>   meta/recipes-extended/iputils/iputils_s20101006.bb |   13 ++---
>   meta/recipes-extended/texinfo/texinfo_4.13a.bb     |   26 ++++++-----
>   5 files changed, 90 insertions(+), 25 deletions(-)
>   create mode 100644 meta/recipes-devtools/docbook-utils/docbook-utils-native_0.6.14.bb
>
> _______________________________________________
> poky mailing list
> poky@yoctoproject.org
> https://lists.yoctoproject.org/listinfo/poky
>
Merged into Master

Thanks
	Sau!



^ permalink raw reply	[flat|nested] 7+ messages in thread

end of thread, other threads:[~2011-02-22 15:49 UTC | newest]

Thread overview: 7+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-02-16  4:32 [PATCH 0/5] docbook-utils and friends Scott Garman
2011-02-16  4:32 ` [PATCH 1/5] texinfo: recipe cleanup, add native support Scott Garman
2011-02-16  4:33 ` [PATCH 2/5] sgml-common-native: fix license info and checksum fields Scott Garman
2011-02-16  4:33 ` [PATCH 3/5] docbook-utils-native: new recipe v0.6.14 Scott Garman
2011-02-16  4:33 ` [PATCH 4/5] opensp: improve configuration and install steps Scott Garman
2011-02-16  4:33 ` [PATCH 5/5] iputils: enable generation of man pages Scott Garman
2011-02-22 15:49 ` [PATCH 0/5] docbook-utils and friends Saul Wold

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox