[meta-virtualization][wrynose][PATCH 1/2] openvswitch: update to 3.7.1

[meta-virtualization][wrynose][PATCH 1/2] openvswitch: update to 3.7.1

[Haitao Liu]

pick up the following commits:

    7921d9c69 Set release date for 3.7.1.
    e1b82e9b7 github: Temporarily disable system tests for DPDK and AF_XDP.
    a9785c7e1 conntrack: Fix replace_substring to handle larger packets.
    7dc6fb7ba Update DPDK version for older releases to 23.11.6 and 24.11.4.

Signed-off-by: Haitao Liu <haitao.liu@windriver.com>
---
 recipes-networking/openvswitch/openvswitch_git.bb | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/recipes-networking/openvswitch/openvswitch_git.bb b/recipes-networking/openvswitch/openvswitch_git.bb
index 87790090..8dcb7ca4 100644
--- a/recipes-networking/openvswitch/openvswitch_git.bb
+++ b/recipes-networking/openvswitch/openvswitch_git.bb
@@ -13,12 +13,12 @@ RDEPENDS:${PN}-ptest += "\
 	python3-resource findutils which diffutils \
 	"
 
-PV = "3.7.0"
+PV = "3.7.1"
 CVE_VERSION = "3.5.0"
 
 FILESEXTRAPATHS:append := "${THISDIR}/${PN}-git:"
 
-SRCREV = "0d4c78e153d2b22ab1b173cd4a4dfff89002666d"
+SRCREV = "7921d9c6924b8934ea1de9481891ac1172649280"
 SRC_URI += "git://github.com/openvswitch/ovs.git;protocol=https;branch=branch-3.7 \
             file://openvswitch-add-ptest-71d553b995d0bd527d3ab1e9fbaf5a2ae34de2f3.patch \
             file://run-ptest \
-- 
2.34.1

[meta-virtualization][wrynose][PATCH 2/2] openvswitch: re-enable ptest

[Haitao Liu]

Ptest support was disabled in commit 816d4c6e0e7c due to breakage in
source handling that prevented proper installation of test files.

Fix the ptest installation by:
  - Copying test binaries from the build directory, preserving subdirectory
    structure (e.g., oss-fuzz/) for optional test components
  - Installing *.at test definitions and *.py test scripts from the source tree
  - Fixing PYTHONPATH in atlocal to use runtime paths instead of build paths
  - Symlinking schema files already provided by the main package to avoid
    file duplication

Re-enable ptest now that installation works correctly.

Test results on genericx86-64:

PASS: checkpatch - catastrophic backtracking
PASS: checkpatch - Unicode code
PASS: appctl-bashcomp - complex completion check 4
PASS: appctl-bashcomp - complex completion check 2
PASS: checkpatch - check misuse APIs
PASS: checkpatch - whitespace around cast
PASS: checkpatch - comments
PASS: checkpatch - check egrep / fgrep
PASS: checkpatch - file contents checks - bare return
PASS: checkpatch - subject
PASS: appctl-bashcomp - negative test
...
...
...
PASS: drop-stats - bridge sampling
PASS: drop-stats - sampling action
PASS: ovsdb-idl - Check Python IDL reconnects to leader - Python3 (leader only)
PASS: monitor-cond-change with many sessions pending

2658 tests were successful.
89 tests were skipped.

Signed-off-by: Haitao Liu <haitao.liu@windriver.com>
---
 .../openvswitch/openvswitch_git.bb            | 59 ++++++++++++++++++-
 1 file changed, 56 insertions(+), 3 deletions(-)

diff --git a/recipes-networking/openvswitch/openvswitch_git.bb b/recipes-networking/openvswitch/openvswitch_git.bb
index 8dcb7ca4..a6b72b86 100644
--- a/recipes-networking/openvswitch/openvswitch_git.bb
+++ b/recipes-networking/openvswitch/openvswitch_git.bb
@@ -20,7 +20,6 @@ FILESEXTRAPATHS:append := "${THISDIR}/${PN}-git:"
 
 SRCREV = "7921d9c6924b8934ea1de9481891ac1172649280"
 SRC_URI += "git://github.com/openvswitch/ovs.git;protocol=https;branch=branch-3.7 \
-            file://openvswitch-add-ptest-71d553b995d0bd527d3ab1e9fbaf5a2ae34de2f3.patch \
             file://run-ptest \
             file://disable_m4_check.patch \
             file://systemd-update-tool-paths.patch \
@@ -50,6 +49,60 @@ inherit ptest
 EXTRA_OEMAKE += "TEST_DEST=${D}${PTEST_PATH} TEST_ROOT=${PTEST_PATH}"
 
 do_install_ptest() {
-	echo "disabled: oe_runmake test-install"
-}
 
+    install -d ${D}${PTEST_PATH}/tests/
+
+    install -m 0644 ${B}/tests/atlocal ${B}/tests/atconfig ${D}${PTEST_PATH}/tests/
+
+    # Copy test binaries into the ptest directory, preserving subdirectory structure.
+    # Use -maxdepth 2 because subdirectories like oss-fuzz/ are not enabled by default;
+    # when enabled, their binaries (e.g., ./oss-fuzz/oss) need to be copied as well.
+    cd ${B}/tests && find . -maxdepth 2 -type f -executable | xargs -I {} cp --parents {} ${D}${PTEST_PATH}/tests/
+    cd ${S}/tests && find . -maxdepth 1 -name '*.at' | xargs -I {} cp --parents {} ${D}${PTEST_PATH}/tests/
+    cd ${S}/tests && find . -maxdepth 1 -type f -executable | xargs -I {} cp --parents {} ${D}${PTEST_PATH}/tests/
+
+    cd ${S}/tests && find . -maxdepth 1 -name '*.py' -exec install -m 0755 {} ${D}${PTEST_PATH}/tests/ \;
+
+    install -D -m 0644 ${S}/vswitchd/vswitch.ovsschema ${D}${PTEST_PATH}/vswitchd/vswitch.ovsschema
+
+    install -D -m 0755 ${S}/utilities/checkpatch.py ${D}${PTEST_PATH}/utilities/checkpatch.py
+    install -D -m 0644 ${S}/utilities/ovs-pcap.in ${D}${PTEST_PATH}/utilities/ovs-pcap.in
+    install -D -m 0644 ${S}/utilities/ovs-pki.in  ${D}${PTEST_PATH}/utilities/ovs-pki.in
+
+    install -D -m 0644 ${S}/python/test_requirements.txt ${D}${PTEST_PATH}/python/test_requirements.txt
+    install -m 0644 ${S}/tests/idltest.ovsschema ${D}${PTEST_PATH}/tests/
+    install -m 0644 ${S}/tests/idltest2.ovsschema ${D}${PTEST_PATH}/tests/
+    install -m 0644 ${S}/AUTHORS.rst ${D}${PTEST_PATH}/
+    install -D -m 0644 ${S}/build-aux/check-structs ${D}${PTEST_PATH}/build-aux/check-structs
+
+    # Symlink vtep.ovsschema to the path expected by ptest; the actual file is
+    # already installed by the main openvswitch package.
+    install -d ${D}${PTEST_PATH}/vtep
+    ln -sf /usr/share/openvswitch/vtep.ovsschema ${D}${PTEST_PATH}/vtep/vtep.ovsschema
+
+    sed  -i \
+         -e 's|PYTHON=.*|PYTHON="python3"|' \
+         -e 's|PYTHONPATH=.*|PYTHONPATH=/usr/share/openvswitch/python:${PTEST_PATH}/tests:$PYTHONPATH|' \
+         -e 's|EGREP=.*|EGREP='"'"'grep -E'"'"'|g' \
+         -e 's|CFLAGS=.*|CFLAGS='"'"' '"'"'|g' \
+         ${D}${PTEST_PATH}/tests/atlocal
+
+    sed -i \
+        -e "s|^at_testdir=.*|at_testdir='${PTEST_PATH}'|" \
+        -e "s|^abs_builddir=.*|abs_builddir='${PTEST_PATH}'|" \
+        -e "s|^at_srcdir=.*|at_srcdir='${PTEST_PATH}/tests'|" \
+        -e "s|^abs_srcdir=.*|abs_srcdir='${PTEST_PATH}/tests'|" \
+        -e "s|^at_top_srcdir=.*|at_top_srcdir='${PTEST_PATH}'|" \
+        -e "s|^abs_top_srcdir=.*|abs_top_srcdir='${PTEST_PATH}'|" \
+        -e "s|^at_top_build_prefix=.*|at_top_build_prefix='${PTEST_PATH}'|" \
+        -e "s|^abs_top_builddir=.*|abs_top_builddir='${PTEST_PATH}'|" \
+         ${D}${PTEST_PATH}/tests/atconfig
+
+    sed -i \
+        -e "s|ovs-appctl-bashcomp\.bash|/etc/bash_completion.d/ovs-appctl-bashcomp\.bash|g" \
+        -e "s|ovs-vsctl-bashcomp\.bash|/etc/bash_completion.d/ovs-vsctl-bashcomp\.bash|g"   \
+        -e "s|^\(.*config\.log.*\)|#\1|g" \
+         ${D}${PTEST_PATH}/tests/testsuite
+}
+RDEPENDS:${PN}-ptest += " ${PN}-testcontroller"
+RDEPENDS:${PN}-ptest += "python3-packaging python3-setuptools"
-- 
2.34.1

Re: [meta-virtualization][wrynose][PATCH 2/2] openvswitch: re-enable ptest

[Bruce Ashfield]

Merged into wrynose as e79d06b1.

The 1/2 (3.7.0 -> 3.7.1) wasn't in my queue anymore, so I
cherry-picked the master commit instead (now fc50b4d9 on wrynose).
Master's SRCREV is slightly past the v3.7.1 tag itself — the same
content but a few post-tag nits.

I also had to retarget the context SRCREV on your ptest patch since
it was built against the v3.7.1 tag exactly and we landed at v3.7.1-tip.
No functional change.

Thanks.

Bruce

Re: [meta-virtualization][wrynose][PATCH 1/2] openvswitch: update to 3.7.1

[Bruce Ashfield]

In message: [meta-virtualization][wrynose][PATCH 1/2] openvswitch: update to 3.7.1
on 01/06/2026 jason.lau via lists.yoctoproject.org wrote:

> pick up the following commits:
> 
>     7921d9c69 Set release date for 3.7.1.
>     e1b82e9b7 github: Temporarily disable system tests for DPDK and AF_XDP.
>     a9785c7e1 conntrack: Fix replace_substring to handle larger packets.
>     7dc6fb7ba Update DPDK version for older releases to 23.11.6 and 24.11.4.
> 
> Signed-off-by: Haitao Liu <haitao.liu@windriver.com>
> ---
>  recipes-networking/openvswitch/openvswitch_git.bb | 4 ++--
>  1 file changed, 2 insertions(+), 2 deletions(-)
> 
> diff --git a/recipes-networking/openvswitch/openvswitch_git.bb b/recipes-networking/openvswitch/openvswitch_git.bb
> index 87790090..8dcb7ca4 100644
> --- a/recipes-networking/openvswitch/openvswitch_git.bb
> +++ b/recipes-networking/openvswitch/openvswitch_git.bb
> @@ -13,12 +13,12 @@ RDEPENDS:${PN}-ptest += "\
>  	python3-resource findutils which diffutils \
>  	"
>  
> -PV = "3.7.0"
> +PV = "3.7.1"
>  CVE_VERSION = "3.5.0"

Not related to your patch, but it looks like I missed the
CVE_VERSION.

Can you do a v2 with that fixed to match PV ?

Bruce

>  
>  FILESEXTRAPATHS:append := "${THISDIR}/${PN}-git:"
>  
> -SRCREV = "0d4c78e153d2b22ab1b173cd4a4dfff89002666d"
> +SRCREV = "7921d9c6924b8934ea1de9481891ac1172649280"
>  SRC_URI += "git://github.com/openvswitch/ovs.git;protocol=https;branch=branch-3.7 \
>              file://openvswitch-add-ptest-71d553b995d0bd527d3ab1e9fbaf5a2ae34de2f3.patch \
>              file://run-ptest \
> -- 
> 2.34.1
> 

> 
> -=-=-=-=-=-=-=-=-=-=-=-
> Links: You receive all messages sent to this group.
> View/Reply Online (#9834): https://lists.yoctoproject.org/g/meta-virtualization/message/9834
> Mute This Topic: https://lists.yoctoproject.org/mt/119587461/1050810
> Group Owner: meta-virtualization+owner@lists.yoctoproject.org
> Unsubscribe: https://lists.yoctoproject.org/g/meta-virtualization/unsub [bruce.ashfield@gmail.com]
> -=-=-=-=-=-=-=-=-=-=-=-
>