[PATCH] add hotplug2 package

[PATCH] add hotplug2 package

[Angus Ainslie]

---
 conf/checksums.ini                        |    4 +++
 packages/hotplug2/hotplug2_0.9+1.0beta.bb |   31
+++++++++++++++++++++++++++++
 2 files changed, 35 insertions(+), 0
deletions(-)                             
 create mode 100644 packages/hotplug2/hotplug2_0.9
+1.0beta.bb                  

diff --git a/conf/checksums.ini b/conf/checksums.ini
index 9548a02..c5e6910 100644                       
--- a/conf/checksums.ini                            
+++ b/conf/checksums.ini                            
@@ -9318,6 +9318,10 @@
sha256=af40399fe434678454ae8ea100db6cba0482aa65b8972a05098c779cac57bc48

md5=faa08f321fefd2c61ce4c9355a62fe31                                                         

sha256=ca7ef124cde06883fbf28c7e78ce1e4c5526434bbe5672ef0a3e85a61a9d0b5f                      
                                                                                              
+[http://isteve.bofh.cz/~isteve/hotplug2/downloads/hotplug2-1.0-beta.tar.gz]                  
+md5=353656ea499d395260c0de143983da4d                                                         
+sha256=54e2fa375506d92a8ac94b5ed332c4c0bf1b69c252692b332c92702670bba583                      
+                                                                                             

[http://www.porchdogsoft.com/download/howl-0.9.7.tar.gz]                                     

md5=85fbe016e2ebad99108b1212ae4b1d6f                                                         

sha256=f8766c44291aac92b2b4abc762e1b11e3504dd9f2a855fdde371b5abd730fe9f                      
diff --git a/packages/hotplug2/hotplug2_0.9+1.0beta.bb
b/packages/hotplug2/hotplug2_0.9+1.0beta.bb
new file mode 100644
index 0000000..8ae5149
--- /dev/null
+++ b/packages/hotplug2/hotplug2_0.9+1.0beta.bb
@@ -0,0 +1,31 @@
+DESCRIPTION = "hotplug2 is a daemon which dynamically creates and
removes device nodes from \
+/dev/, handles hotplug events and loads drivers at boot time. It
replaces \
+the hotplug and udev packages and requires a kernel not older than
2.6.12."
+RPROVIDES_${PN} = "hotplug"
+RREPLACES_${PN} = "udev"
+PR = "r0"
+
+SRC_URI =
"http://isteve.bofh.cz/~isteve/hotplug2/downloads/hotplug2-1.0-beta.tar.gz \
+           "
+
+S = "${WORKDIR}/hotplug2-1.0-beta"
+
+DEFAULT_PREFERENCE = "-1"
+
+inherit autotools
+
+INITSCRIPT_PARAMS = "start 03 S ."
+
+LDFLAGS += "-lglibc"
+DESTDIR=${D}
+
+do_configure () {
+}
+
+do_install_prepend () {
+        install -d ${D}/lib/hotplug2
+        install -d ${D}/sbin
+}
+
+FILES_${PN} += "${base_libdir}/hotplug2/*"
+FILES_${PN}-dbg += "${base_libdir}/hotplug2/.debug"
--
1.5.6.3

Re: [PATCH] add hotplug2 package

[Koen Kooi]

On 31-03-09 00:40, Angus Ainslie wrote:

Your commit message is invalid



> +PR = "r0"

r0 is the default so you can remove that


> +DEFAULT_PREFERENCE = "-1"

There's only one version of hotplug2, so why add a default_pref?


> +INITSCRIPT_PARAMS = "start 03 S ."

You forgot to inherit update-rc.d

> +LDFLAGS += "-lglibc"

I don't think that actually works, and if it did, uclibc would break


> +DESTDIR=${D}

missing quotes

> +do_configure () {
> +}

missing colon between the braces. But more importantly: why inherit 
autotools when you're not going to run configure?

regards,

Koen

Re: [PATCH] add hotplug2 package

[Angus Ainslie]

[-- Attachment #1: Type: text/plain, Size: 1661 bytes --]

On Tue, 2009-03-31 at 08:53 +0200, Koen Kooi wrote:
> On 31-03-09 00:40, Angus Ainslie wrote:
> 
> Your commit message is invalid
> 
> 

Thanks for pointing out the problem. I would find it helpful if you gave
a hint about what might be invalid. Hopefully this is corrected.


> 
> > +PR = "r0"
> 
> r0 is the default so you can remove that
> 

fixed

> 
> > +DEFAULT_PREFERENCE = "-1"
> 
> There's only one version of hotplug2, so why add a default_pref?
> 

I had 2 on my system but only chose to submit this one. Fixed.

> 
> > +INITSCRIPT_PARAMS = "start 03 S ."
> 
> You forgot to inherit update-rc.d
> 

fixed 

> > +LDFLAGS += "-lglibc"
> 
> I don't think that actually works, and if it did, uclibc would break
> 

Without that I get undefined refeences

 loader.c:(.text+0x14): undefined reference to `dlclose'
 workers/loader.o: In function `worker_load':
 loader.c:(.text+0x44): undefined reference to `dlopen'
 loader.c:(.text+0x5c): undefined reference to `dlsym'
 loader.c:(.text+0x84): undefined reference to `dlerror'

> 
> > +DESTDIR=${D}
> 
> missing quotes
> 

fixed

> > +do_configure () {
> > +}
> 
> missing colon between the braces. But more importantly: why inherit 
> autotools when you're not going to run configure?
> 

I was under the mistaken impression that autotools need to be included
to get do_compile() and do_install(). It seems those are the defaults.

There is a deeper problem that without the inherit autotools then the
LDFLAGS above fails to find glibc. Is there something missing in the
default case ?


> regards,
> 
> Koen
> 

Thanks
Angus

[-- Attachment #2: 0001-hotplug2-added-new-recipe-and-updated-checksums.ini.patch --]
[-- Type: text/x-patch, Size: 2284 bytes --]

From 24de7beb1d43caab4e3a59bb4de78e0449e47dfc Mon Sep 17 00:00:00 2001
From: Angus Ainslie <nytowl@openmoko.org>
Date: Tue, 31 Mar 2009 08:56:46 -0600
Subject: [PATCH] hotplug2: added new recipe and updated checksums.ini

---
 conf/checksums.ini                        |    4 +++
 packages/hotplug2/hotplug2_0.9+1.0beta.bb |   30 +++++++++++++++++++++++++++++
 2 files changed, 34 insertions(+), 0 deletions(-)
 create mode 100644 packages/hotplug2/hotplug2_0.9+1.0beta.bb

diff --git a/conf/checksums.ini b/conf/checksums.ini
index 9548a02..c5e6910 100644
--- a/conf/checksums.ini
+++ b/conf/checksums.ini
@@ -9318,6 +9318,10 @@ sha256=af40399fe434678454ae8ea100db6cba0482aa65b8972a05098c779cac57bc48
 md5=faa08f321fefd2c61ce4c9355a62fe31
 sha256=ca7ef124cde06883fbf28c7e78ce1e4c5526434bbe5672ef0a3e85a61a9d0b5f
 
+[http://isteve.bofh.cz/~isteve/hotplug2/downloads/hotplug2-1.0-beta.tar.gz]
+md5=353656ea499d395260c0de143983da4d
+sha256=54e2fa375506d92a8ac94b5ed332c4c0bf1b69c252692b332c92702670bba583
+
 [http://www.porchdogsoft.com/download/howl-0.9.7.tar.gz]
 md5=85fbe016e2ebad99108b1212ae4b1d6f
 sha256=f8766c44291aac92b2b4abc762e1b11e3504dd9f2a855fdde371b5abd730fe9f
diff --git a/packages/hotplug2/hotplug2_0.9+1.0beta.bb b/packages/hotplug2/hotplug2_0.9+1.0beta.bb
new file mode 100644
index 0000000..1702c4f
--- /dev/null
+++ b/packages/hotplug2/hotplug2_0.9+1.0beta.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "hotplug2 is a daemon which dynamically creates and removes device nodes from \
+/dev/, handles hotplug events and loads drivers at boot time. It replaces \
+the hotplug and udev packages and requires a kernel not older than 2.6.12."
+RPROVIDES_${PN} = "hotplug"
+RREPLACES_${PN} = "udev"
+
+SRC_URI = "http://isteve.bofh.cz/~isteve/hotplug2/downloads/hotplug2-1.0-beta.tar.gz \
+           "
+
+S = "${WORKDIR}/hotplug2-1.0-beta"
+
+inherit update-rc.d autotools
+
+INITSCRIPT_PARAMS = "start 03 S ."
+INITSCRIPT_NAME = "hotplug2"
+
+LDFLAGS += "-lglibc"
+DESTDIR="${D}"
+
+do_configure() {
+:
+}
+
+do_install_prepend () {
+        install -d ${D}/lib/hotplug2
+        install -d ${D}/sbin
+}
+
+FILES_${PN} += "${base_libdir}/hotplug2/*"
+FILES_${PN}-dbg += "${base_libdir}/hotplug2/.debug"
-- 
1.5.6.3

Re: [PATCH] add hotplug2 package

[Denys Dmytriyenko]

On Tue, Mar 31, 2009 at 09:01:17AM -0600, Angus Ainslie wrote:
> > > +LDFLAGS += "-lglibc"
> > 
> > I don't think that actually works, and if it did, uclibc would break
> 
> Without that I get undefined refeences
> 
>  loader.c:(.text+0x14): undefined reference to `dlclose'
>  workers/loader.o: In function `worker_load':
>  loader.c:(.text+0x44): undefined reference to `dlopen'
>  loader.c:(.text+0x5c): undefined reference to `dlsym'
>  loader.c:(.text+0x84): undefined reference to `dlerror'
> 
> > > +do_configure () {
> > > +}
> > 
> > missing colon between the braces. But more importantly: why inherit 
> > autotools when you're not going to run configure?
> 
> I was under the mistaken impression that autotools need to be included
> to get do_compile() and do_install(). It seems those are the defaults.
> 
> There is a deeper problem that without the inherit autotools then the
> LDFLAGS above fails to find glibc. Is there something missing in the
> default case ?

Wow, I'm surprised "-lglibc" above even worked for you:

$ find rootfs -name 'libglibc*'
$

Those undefined references above are provided by libdl.so, which needs:

LDFLAGS += " -ldl"

And no need for autotools.

-- 
Denys

Re: [PATCH] add hotplug2 package

[Angus Ainslie]

[-- Attachment #1: Type: text/plain, Size: 409 bytes --]

On Tue, 2009-03-31 at 18:14 -0400, Denys Dmytriyenko wrote:
> 
> Wow, I'm surprised "-lglibc" above even worked for you:
> 
> $ find rootfs -name 'libglibc*'
> $
> 
> Those undefined references above are provided by libdl.so, which needs:
> 
> LDFLAGS += " -ldl"
> 
> And no need for autotools.
> 

Weird, I was sure I'd tried it that way the first time. Here's the
updated recipe.

Angus


[-- Attachment #2: 0001-hotplug2-added-new-recipe-and-updated-checksums.ini.patch --]
[-- Type: text/x-patch, Size: 2239 bytes --]

From 055519888c8d279e83ce11337746400343addb7c Mon Sep 17 00:00:00 2001
From: Angus Ainslie <nytowl@openmoko.org>
Date: Tue, 31 Mar 2009 08:56:46 -0600
Subject: [PATCH] hotplug2: added new recipe and updated checksums.ini

---
 conf/checksums.ini                        |    4 ++++
 packages/hotplug2/hotplug2_0.9+1.0beta.bb |   26 ++++++++++++++++++++++++++
 2 files changed, 30 insertions(+), 0 deletions(-)
 create mode 100644 packages/hotplug2/hotplug2_0.9+1.0beta.bb

diff --git a/conf/checksums.ini b/conf/checksums.ini
index 9548a02..c5e6910 100644
--- a/conf/checksums.ini
+++ b/conf/checksums.ini
@@ -9318,6 +9318,10 @@ sha256=af40399fe434678454ae8ea100db6cba0482aa65b8972a05098c779cac57bc48
 md5=faa08f321fefd2c61ce4c9355a62fe31
 sha256=ca7ef124cde06883fbf28c7e78ce1e4c5526434bbe5672ef0a3e85a61a9d0b5f
 
+[http://isteve.bofh.cz/~isteve/hotplug2/downloads/hotplug2-1.0-beta.tar.gz]
+md5=353656ea499d395260c0de143983da4d
+sha256=54e2fa375506d92a8ac94b5ed332c4c0bf1b69c252692b332c92702670bba583
+
 [http://www.porchdogsoft.com/download/howl-0.9.7.tar.gz]
 md5=85fbe016e2ebad99108b1212ae4b1d6f
 sha256=f8766c44291aac92b2b4abc762e1b11e3504dd9f2a855fdde371b5abd730fe9f
diff --git a/packages/hotplug2/hotplug2_0.9+1.0beta.bb b/packages/hotplug2/hotplug2_0.9+1.0beta.bb
new file mode 100644
index 0000000..564785d
--- /dev/null
+++ b/packages/hotplug2/hotplug2_0.9+1.0beta.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "hotplug2 is a daemon which dynamically creates and removes device nodes from \
+/dev/, handles hotplug events and loads drivers at boot time. It replaces \
+the hotplug and udev packages and requires a kernel not older than 2.6.12."
+RPROVIDES_${PN} = "hotplug"
+RREPLACES_${PN} = "udev"
+
+SRC_URI = "http://isteve.bofh.cz/~isteve/hotplug2/downloads/hotplug2-1.0-beta.tar.gz \
+           "
+
+S = "${WORKDIR}/hotplug2-1.0-beta"
+
+inherit update-rc.d
+
+INITSCRIPT_PARAMS = "start 03 S ."
+INITSCRIPT_NAME = "hotplug2"
+
+LDFLAGS += "-ldl"
+DESTDIR="${D}"
+
+do_install_prepend () {
+        install -d ${D}/lib/hotplug2
+        install -d ${D}/sbin
+}
+
+FILES_${PN} += "${base_libdir}/hotplug2/*"
+FILES_${PN}-dbg += "${base_libdir}/hotplug2/.debug"
-- 
1.5.6.3

Re: [PATCH] add hotplug2 package

[Koen Kooi]

On 01-04-09 15:08, Angus Ainslie wrote:

> Weird, I was sure I'd tried it that way the first time. Here's the
> updated recipe.

+RPROVIDES_${PN} = "hotplug"
+RREPLACES_${PN} = "udev"

What happens if both hotplug2 and udev and in deploy and I want to 
install udev? I suspect it will silently select hotplug2, which is not 
what we want.

So: NAK

regards,

Koen