[cocci] Can Coccinell concatinate or append to existing string literals?

[cocci] Can Coccinell concatinate or append to existing string literals?

[Eric Wheeler]

Hello,

I would like to do something like this:

	@ a @
	constant C;
	constant CN ## "_bar";
	@@
	-foo(C);
	+foo(CN);

to produce this:

	void f()
	{
	-	foo("foo");
	+	foo("foo_bar");
	}

It looks like `fresh identifier` can do something like this, but I can't 
get it to work with strings.  Is there a way?


--
Eric Wheeler

Re: [cocci] Can Coccinell concatinate or append to existing string literals?

[Julia Lawall]

On Sat, 12 Mar 2022, Eric Wheeler wrote:

> Hello,
>
> I would like to do something like this:
>
> 	@ a @
> 	constant C;
> 	constant CN ## "_bar";
> 	@@
> 	-foo(C);
> 	+foo(CN);
>
> to produce this:
>
> 	void f()
> 	{
> 	-	foo("foo");
> 	+	foo("foo_bar");
> 	}
>
> It looks like `fresh identifier` can do something like this, but I can't
> get it to work with strings.  Is there a way?

Please take a look at demos/pythontococci.cocci
By using python scripting, you can do whatever you want.

julia

Re: [cocci] Can Coccinelle concatenate or append to existing string literals?

[Markus Elfring]

> to produce this:
>
> 	void f()
> 	{
> 	-	foo("foo");
> 	+	foo("foo_bar");
> 	}
>
> It looks like `fresh identifier` can do something like this,
> but I can't get it to work with strings.


I suggest to increase the distinction which data parts you would like to modify
for such a transformation attempt.



> Is there a way?


Will another test result for a SmPL script like the following trigger any further
collateral evolution?

@addition@
@@
 void f()
 {
 foo("foo"
+    "_bar"
    );
 }


Markus_Elfring@Sonne:…Projekte/Coccinelle/Probe> spatch --parse-cocci append_to_string_literal1.cocci
…
plus: parse error:
  File "append_to_string_literal1.cocci", line 6, column 10, charpos = 48
  around = '"',
  whole content = +    "_bar"


How will the chances evolve to support string literal concatenations better here
(by the means of the semantic patch language)?
https://en.cppreference.com/w/c/language/string_literal#Explanation


@initialize:python@
@@
import re

@find_update_candidate@
constant input_string;
position pos;
@@
 void f()
 {
 foo@pos(input_string);
 }

@script:python selection@
param << find_update_candidate.input_string;
text;
@@
if param == '"foo"':
   coccinelle.text = cocci.make_expr('"foo_bar"')
else:
   cocci.include_match(False)

@replacement@
constant find_update_candidate.input_string, selection.text;
position find_update_candidate.pos;
@@
 void f()
 {
 foo@pos(
-        input_string
+        text
        );
 }


Markus_Elfring@Sonne:…Projekte/Coccinelle/Probe> spatch append_to_string_literal2.cocci string_literal_usage1.c
…
@@ -1,4 +1,4 @@
 void f()
 {
-foo("foo");
+foo("foo_bar");
 }


Regards,
Markus

Re: [cocci] Can Coccinelle concatenate or append to existing string literals?

[Julia Lawall]

[-- Attachment #1: Type: text/plain, Size: 2218 bytes --]



On Sun, 13 Mar 2022, Markus Elfring wrote:

>
> > to produce this:
> >
> > 	void f()
> > 	{
> > 	-	foo("foo");
> > 	+	foo("foo_bar");
> > 	}
> >
> > It looks like `fresh identifier` can do something like this,
> > but I can't get it to work with strings.
>
>
> I suggest to increase the distinction which data parts you would like to modify
> for such a transformation attempt.
>
>
>
> > Is there a way?
>
>
> Will another test result for a SmPL script like the following trigger any further
> collateral evolution?
>
> @addition@
> @@
>  void f()
>  {
>  foo("foo"
> +    "_bar"
>     );
>  }

Maybe this would be a good thing in principle, but I don't think it would
be the desirable solution in Eric's case.  He should just use python to
construct the string he wants.  In that way, the user will better be able
to connect the output to the string that is found in the code.

julia


>
>
> Markus_Elfring@Sonne:…Projekte/Coccinelle/Probe> spatch --parse-cocci append_to_string_literal1.cocci
> …
> plus: parse error:
>   File "append_to_string_literal1.cocci", line 6, column 10, charpos = 48
>   around = '"',
>   whole content = +    "_bar"
>
>
> How will the chances evolve to support string literal concatenations better here
> (by the means of the semantic patch language)?
> https://en.cppreference.com/w/c/language/string_literal#Explanation
>
>
> @initialize:python@
> @@
> import re
>
> @find_update_candidate@
> constant input_string;
> position pos;
> @@
>  void f()
>  {
>  foo@pos(input_string);
>  }
>
> @script:python selection@
> param << find_update_candidate.input_string;
> text;
> @@
> if param == '"foo"':
>    coccinelle.text = cocci.make_expr('"foo_bar"')
> else:
>    cocci.include_match(False)
>
> @replacement@
> constant find_update_candidate.input_string, selection.text;
> position find_update_candidate.pos;
> @@
>  void f()
>  {
>  foo@pos(
> -        input_string
> +        text
>         );
>  }
>
>
> Markus_Elfring@Sonne:…Projekte/Coccinelle/Probe> spatch append_to_string_literal2.cocci string_literal_usage1.c
> …
> @@ -1,4 +1,4 @@
>  void f()
>  {
> -foo("foo");
> +foo("foo_bar");
>  }
>
>
> Regards,
> Markus
>
>

Re: [cocci] Can Coccinelle concatenate or append to existing string literals?

[Markus Elfring]

>> Will another test result for a SmPL script like the following trigger any further
>> collateral evolution?
>>
>> @addition@
>> @@
>>  void f()
>>  {
>>  foo("foo"
>> +    "_bar"
>>     );
>>  }
> Maybe this would be a good thing in principle,


Will the chances grow to improve Coccinelle software components
so that similarly simple source code adjustments will become directly supported?



> but I don't think it would be the desirable solution in Eric's case.


I am curious how the extended transformation approach will look like.



> He should just use python to construct the string he wants.


Other scripting languages (OCaml for example) can provide further design options.



> In that way, the user will better be able to connect the output to the string
> that is found in the code.


How many development efforts would you like to invest for expressing desirable changes
in a succinct way?

Regards,
Markus

Re: [cocci] Can Coccinell concatinate or append to existing string literals?

[Luis Chamberlain]

On Sat, Mar 12, 2022 at 04:53:22PM -0800, Eric Wheeler wrote:
> Hello,
> 
> I would like to do something like this:
> 
> 	@ a @
> 	constant C;
> 	constant CN ## "_bar";
> 	@@
> 	-foo(C);
> 	+foo(CN);
> 
> to produce this:
> 
> 	void f()
> 	{
> 	-	foo("foo");
> 	+	foo("foo_bar");
> 	}
> 
> It looks like `fresh identifier` can do something like this, but I can't 
> get it to work with strings.  Is there a way?

Yes sure below is an example I used recently in Linux:

@c1@
expression E1;
identifier subdir, sysctls;
@@

static struct ctl_table subdir[] = {
    {
	    .procname = E1,
	    .maxlen = 0,
	    .mode = 0555,
	    .child = sysctls,
    },
    { }
};

@c2@
identifier c1.subdir;

expression E2;
identifier base;
@@

static struct ctl_table base[] = {
    {
	    .procname = E2,
	    .maxlen = 0,
	    .mode = 0555,
	    .child = subdir,
    },
    { }
};

@c3@
identifier c2.base;
identifier header;
@@

header = register_sysctl_table(base);

@r1 depends on c1 && c2 && c3@
expression c1.E1;
identifier c1.subdir, c1.sysctls;
@@

-static struct ctl_table subdir[] = {
-       {
-               .procname = E1,
-               .maxlen = 0,
-               .mode = 0555,
-               .child = sysctls,
-       },
-       { }
-};

@r2 depends on c1 && c2 && c3@
identifier c1.subdir;

expression c2.E2;
identifier c2.base;
@@
-static struct ctl_table base[] = {
-       {
-               .procname = E2,
-               .maxlen = 0,
-               .mode = 0555,
-               .child = subdir,
-       },
-       { }
-};

@initialize:python@
@@

def make_my_fresh_expression(s1, s2):
return '"' + s1.strip('"') + "/" + s2.strip('"') + '"'

@r3 depends on c1 && c2 && c3@
expression c1.E1;
identifier c1.sysctls;
expression c2.E2;
identifier c2.base;
identifier c3.header;
fresh identifier E3 = script:python(E2, E1) { make_my_fresh_expression(E2, E1) };
@@

header =
-register_sysctl_table(base);
+register_sysctl(E3, sysctls);

Re: [cocci] Can Coccinelle concatenate or append to existing string literals?

[Markus Elfring]

…

> @initialize:python@
> @@
>
> def make_my_fresh_expression(s1, s2):
> return '"' + s1.strip('"') + "/" + s2.strip('"') + '"'
>
> @r3 depends on c1 && c2 && c3@
> expression c1.E1;
> identifier c1.sysctls;
> expression c2.E2;
> identifier c2.base;
> identifier c3.header;
> fresh identifier E3 = script:python(E2, E1) { make_my_fresh_expression(E2, E1) };
> @@
>
> header =
> -register_sysctl_table(base);
> +register_sysctl(E3, sysctls);


How relevant is such a SmPL script example (which seems to demonstrate the selection
of a name pattern) when string literals should be constructed?

Regards,
Markus

Re: [cocci] Can Coccinelle concatenate or append to existing string literals?

[Julia Lawall]

[-- Attachment #1: Type: text/plain, Size: 776 bytes --]



On Sun, 13 Mar 2022, Markus Elfring wrote:

> …
>
> > @initialize:python@
> > @@
> >
> > def make_my_fresh_expression(s1, s2):
> > return '"' + s1.strip('"') + "/" + s2.strip('"') + '"'
> >
> > @r3 depends on c1 && c2 && c3@
> > expression c1.E1;
> > identifier c1.sysctls;
> > expression c2.E2;
> > identifier c2.base;
> > identifier c3.header;
> > fresh identifier E3 = script:python(E2, E1) { make_my_fresh_expression(E2, E1) };
> > @@
> >
> > header =
> > -register_sysctl_table(base);
> > +register_sysctl(E3, sysctls);
>
>
> How relevant is such a SmPL script example (which seems to demonstrate the selection
> of a name pattern) when string literals should be constructed?

It shows how to generate noew code from some matched information, as was
asked for.

julia

Re: [cocci] Checking the construction of a fresh identifier

[Markus Elfring]

…
> @initialize:python@
> @@
>
> def make_my_fresh_expression(s1, s2):
> return '"' + s1.strip('"') + "/" + s2.strip('"') + '"'
>
> @r3 depends on c1 && c2 && c3@
> expression c1.E1;
> identifier c1.sysctls;
> expression c2.E2;
> identifier c2.base;
> identifier c3.header;
> fresh identifier E3 = script:python(E2, E1) { make_my_fresh_expression(E2, E1) };
> @@
>
> header =
> -register_sysctl_table(base);
> +register_sysctl(E3, sysctls);


I find it questionable that an “identifier” for the C programming language may contain
quotation characters and a slash.

Do you depend on any special software behaviour here?
https://gitlab.inria.fr/coccinelle/coccinelle/-/blob/20fdb67f4b20a242f222337e13091115884cf6bb/docs/manual/cocci_syntax.tex#L280
https://github.com/coccinelle/coccinelle/blob/ae337fce1512ff15aabc3ad5b6d2e537f97ab62a/docs/manual/cocci_syntax.tex#L280


Regards,
Markus

Re: [cocci] Can Coccinell concatinate or append to existing string literals?

[Eric Wheeler]

On Sun, 13 Mar 2022, Luis Chamberlain wrote:
> On Sat, Mar 12, 2022 at 04:53:22PM -0800, Eric Wheeler wrote:
> > Hello,
> > 
> > I would like to do something like this:
> > 
> > 	@ a @
> > 	constant C;
> > 	constant CN ## "_bar";
> > 	@@
> > 	-foo(C);
> > 	+foo(CN);
> > 
> > to produce this:
> > 
> > 	void f()
> > 	{
> > 	-	foo("foo");
> > 	+	foo("foo_bar");
> > 	}
> > 
> > It looks like `fresh identifier` can do something like this, but I can't 
> > get it to work with strings.  Is there a way?
> 
> Yes sure below is an example I used recently in Linux:
> 
> @c1@
> expression E1;
> identifier subdir, sysctls;
> @@
> 
> static struct ctl_table subdir[] = {
>     {
> 	    .procname = E1,
> 	    .maxlen = 0,
> 	    .mode = 0555,
> 	    .child = sysctls,
>     },
>     { }
> };
> 
> @c2@
> identifier c1.subdir;
> 
> expression E2;
> identifier base;
> @@
> 
> static struct ctl_table base[] = {
>     {
> 	    .procname = E2,
> 	    .maxlen = 0,
> 	    .mode = 0555,
> 	    .child = subdir,
>     },
>     { }
> };
> 
> @c3@
> identifier c2.base;
> identifier header;
> @@
> 
> header = register_sysctl_table(base);
> 
> @r1 depends on c1 && c2 && c3@
> expression c1.E1;
> identifier c1.subdir, c1.sysctls;
> @@
> 
> -static struct ctl_table subdir[] = {
> -       {
> -               .procname = E1,
> -               .maxlen = 0,
> -               .mode = 0555,
> -               .child = sysctls,
> -       },
> -       { }
> -};
> 
> @r2 depends on c1 && c2 && c3@
> identifier c1.subdir;
> 
> expression c2.E2;
> identifier c2.base;
> @@
> -static struct ctl_table base[] = {
> -       {
> -               .procname = E2,
> -               .maxlen = 0,
> -               .mode = 0555,
> -               .child = subdir,
> -       },
> -       { }
> -};
> 
> @initialize:python@
> @@
> 
> def make_my_fresh_expression(s1, s2):
> return '"' + s1.strip('"') + "/" + s2.strip('"') + '"'
> 
> @r3 depends on c1 && c2 && c3@
> expression c1.E1;
> identifier c1.sysctls;
> expression c2.E2;
> identifier c2.base;
> identifier c3.header;
> fresh identifier E3 = script:python(E2, E1) { make_my_fresh_expression(E2, E1) };
> @@
> 
> header =
> -register_sysctl_table(base);
> +register_sysctl(E3, sysctls);
> 


Thanks everyone for answering this thread and providing these examples and 
explanations to reference!

--
Eric Wheeler