[meta-oe][PATCH] fio: Add PACKAGECONFIG for numa, re-enable ARM build

[meta-oe][PATCH] fio: Add PACKAGECONFIG for numa, re-enable ARM build

[Dominic Sacré]

Make fio's NUMA support optional via PACKAGECONFIG.
Enable this feature by default, except on ARM where libnuma/numactl
is not available.

Signed-off-by: Dominic Sacré <dominic.sacre@gmx.de>
---
 meta-oe/recipes-benchmark/fio/fio_2.2.6.bb | 7 +++++--
 1 file changed, 5 insertions(+), 2 deletions(-)

diff --git a/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb b/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
index 82f9cd4..1255441 100644
--- a/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
+++ b/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
@@ -10,10 +10,13 @@ SECTION = "console/tests"
 LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=393a5ca445f6965873eca0259a17f833"
 
-DEPENDS = "libaio zlib numactl"
+DEPENDS = "libaio zlib"
+
+PACKAGECONFIG ??= "numa"
+PACKAGECONFIG[numa] = ",--disable-numa,numactl"
 
 # ARM does not currently support NUMA
-COMPATIBLE_HOST = "^((?!arm).*)$"
+PACKAGECONFIG_remove_arm = "numa"
 
 # rev for v2.2.6
 SRCREV = "f52c9691bc8c285f3445235c69acdfd6de7f9b82"
-- 
2.4.5

Re: [meta-oe][PATCH] fio: Add PACKAGECONFIG for numa, re-enable ARM build

[Andre McCurdy]

Hi Dominic,

On Thu, Jul 16, 2015 at 5:45 AM, Dominic Sacré <dominic.sacre@gmx.de> wrote:
> Make fio's NUMA support optional via PACKAGECONFIG.
> Enable this feature by default, except on ARM where libnuma/numactl
> is not available.
>
> Signed-off-by: Dominic Sacré <dominic.sacre@gmx.de>
> ---
>  meta-oe/recipes-benchmark/fio/fio_2.2.6.bb | 7 +++++--
>  1 file changed, 5 insertions(+), 2 deletions(-)
>
> diff --git a/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb b/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
> index 82f9cd4..1255441 100644
> --- a/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
> +++ b/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
> @@ -10,10 +10,13 @@ SECTION = "console/tests"
>  LICENSE = "GPLv2"
>  LIC_FILES_CHKSUM = "file://COPYING;md5=393a5ca445f6965873eca0259a17f833"
>
> -DEPENDS = "libaio zlib numactl"
> +DEPENDS = "libaio zlib"
> +
> +PACKAGECONFIG ??= "numa"
> +PACKAGECONFIG[numa] = ",--disable-numa,numactl"

I don't think this change will work.

The fio recipe doesn't use autotools, so the --disable-numa option set
via PACKAGECONFIG isn't going to have any effect unless you also
manually pass EXTRA_OECONF into the build somehow.

>  # ARM does not currently support NUMA
> -COMPATIBLE_HOST = "^((?!arm).*)$"
> +PACKAGECONFIG_remove_arm = "numa"

In general, it would be better to use something like:

  PACKAGECONFIG_NUMA = "numa"
  PACKAGECONFIG_NUMA_arm = ""

  PACKAGECONFIG ??= "${PACKAGECONFIG_NUMA}"

_remove can be a little difficult to 'over-ride', so makes things
harder if someone did, one day, want to experiment with enabling that
option from local.conf or a .bbappend.

>  # rev for v2.2.6
>  SRCREV = "f52c9691bc8c285f3445235c69acdfd6de7f9b82"
> --
> 2.4.5
>
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

Re: [meta-oe][PATCH] fio: Add PACKAGECONFIG for numa, re-enable ARM build

[Dominic Sacré]

Hi Andre,

On 2015-07-17 02:46, Andre McCurdy wrote:
>> +PACKAGECONFIG[numa] = ",--disable-numa,numactl"
> 
> I don't think this change will work.
> 
> The fio recipe doesn't use autotools, so the --disable-numa option set
> via PACKAGECONFIG isn't going to have any effect unless you also
> manually pass EXTRA_OECONF into the build somehow.

Ouch, you're right. The configure script is currently only called
indirectly (from the Makefile) and without arguments during do_compile.

How about adding this simple do_configure function?

do_configure() {
    ${B}/configure ${EXTRA_OECONF}
}

>>  # ARM does not currently support NUMA
>> -COMPATIBLE_HOST = "^((?!arm).*)$"
>> +PACKAGECONFIG_remove_arm = "numa"
> 
> In general, it would be better to use something like:
> 
>   PACKAGECONFIG_NUMA = "numa"
>   PACKAGECONFIG_NUMA_arm = ""
> 
>   PACKAGECONFIG ??= "${PACKAGECONFIG_NUMA}"
> 
> _remove can be a little difficult to 'over-ride', so makes things
> harder if someone did, one day, want to experiment with enabling that
> option from local.conf or a .bbappend.

Good point. I thought the _remove was ugly, but it didn't occur to me to
use an additional level of indirection like this.


Dominic

Re: [meta-oe][PATCH] fio: Add PACKAGECONFIG for numa, re-enable ARM build

[Andre McCurdy]

On Fri, Jul 17, 2015 at 7:45 AM, Dominic Sacré <dominic.sacre@gmx.de> wrote:
> Hi Andre,
>
> On 2015-07-17 02:46, Andre McCurdy wrote:
>>> +PACKAGECONFIG[numa] = ",--disable-numa,numactl"
>>
>> I don't think this change will work.
>>
>> The fio recipe doesn't use autotools, so the --disable-numa option set
>> via PACKAGECONFIG isn't going to have any effect unless you also
>> manually pass EXTRA_OECONF into the build somehow.
>
> Ouch, you're right. The configure script is currently only called
> indirectly (from the Makefile) and without arguments during do_compile.
>
> How about adding this simple do_configure function?
>
> do_configure() {
>     ${B}/configure ${EXTRA_OECONF}
> }

Yes, that looks like the right approach. However you should use
"./configure" instead of "${B}/configure".

The configure script is in the source directory, ie ${S}, not the
build directory, and since do_configure is run from within ${S} by
default you don't need the full path.

>>>  # ARM does not currently support NUMA
>>> -COMPATIBLE_HOST = "^((?!arm).*)$"
>>> +PACKAGECONFIG_remove_arm = "numa"
>>
>> In general, it would be better to use something like:
>>
>>   PACKAGECONFIG_NUMA = "numa"
>>   PACKAGECONFIG_NUMA_arm = ""
>>
>>   PACKAGECONFIG ??= "${PACKAGECONFIG_NUMA}"
>>
>> _remove can be a little difficult to 'over-ride', so makes things
>> harder if someone did, one day, want to experiment with enabling that
>> option from local.conf or a .bbappend.
>
> Good point. I thought the _remove was ugly, but it didn't occur to me to
> use an additional level of indirection like this.
>
>
> Dominic
> --
> _______________________________________________
> Openembedded-devel mailing list
> Openembedded-devel@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-devel

[meta-oe][PATCH v2] fio: Add PACKAGECONFIG for numa, re-enable ARM build

[Dominic Sacré]

Make fio's NUMA support optional via PACKAGECONFIG.
Enable this feature by default, except on ARM where libnuma/numactl
is not available.

Signed-off-by: Dominic Sacré <dominic.sacre@gmx.de>
---
 meta-oe/recipes-benchmark/fio/fio_2.2.6.bb | 12 ++++++++++--
 1 file changed, 10 insertions(+), 2 deletions(-)

diff --git a/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb b/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
index 82f9cd4..dca0e64 100644
--- a/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
+++ b/meta-oe/recipes-benchmark/fio/fio_2.2.6.bb
@@ -10,10 +10,14 @@ SECTION = "console/tests"
 LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=393a5ca445f6965873eca0259a17f833"
 
-DEPENDS = "libaio zlib numactl"
+DEPENDS = "libaio zlib"
 
+PACKAGECONFIG_NUMA = "numa"
 # ARM does not currently support NUMA
-COMPATIBLE_HOST = "^((?!arm).*)$"
+PACKAGECONFIG_NUMA_arm = ""
+
+PACKAGECONFIG ??= "${PACKAGECONFIG_NUMA}"
+PACKAGECONFIG[numa] = ",--disable-numa,numactl"
 
 # rev for v2.2.6
 SRCREV = "f52c9691bc8c285f3445235c69acdfd6de7f9b82"
@@ -23,6 +27,10 @@ S = "${WORKDIR}/git"
 
 EXTRA_OEMAKE = "CC='${CC}' LDFLAGS='${LDFLAGS}'"
 
+do_configure() {
+    ./configure ${EXTRA_OECONF}
+}
+
 do_install() {
     oe_runmake install DESTDIR=${D} prefix=${prefix} mandir=${mandir}
     install -d ${D}/${docdir}/${PN}
-- 
2.4.5