[PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Søren Holm]

Signed-off-by: Søren Holm <sgh@sgh.dk>
---
 recipes/wvstreams/wvstreams_4.6.1.bb |   44 ++++++++++++++++++++++++++++++++++
 1 files changed, 44 insertions(+), 0 deletions(-)
 create mode 100644 recipes/wvstreams/wvstreams_4.6.1.bb

diff --git a/recipes/wvstreams/wvstreams_4.6.1.bb b/recipes/wvstreams/wvstreams_4.6.1.bb
new file mode 100644
index 0000000..b11b500
--- /dev/null
+++ b/recipes/wvstreams/wvstreams_4.6.1.bb
@@ -0,0 +1,44 @@
+HOMEPAGE = "http://alumnit.ca/wiki/index.php?page=WvStreams"
+LICENSE = "LGPL"
+DESCRIPTION = "WvStreams is a network programming library in C++"
+DEPENDS = "zlib openssl (>= 0.9.8)"
+
+PR = "r1"
+
+SRC_URI = "http://wvstreams.googlecode.com/files/${PN}-${PV}.tar.gz \
+	file://0001-Fixed-missing-header-includes.patch \
+	"
+
+inherit autotools pkgconfig
+
+LDFLAGS_append = " -Wl,-rpath-link,${TOOLCHAIN_PATH}/${TARGET_SYS}/lib"
+
+# dbus detection currently broken in configure.ac; remember to add "dbus (>= 1.2.14)" to DEPENDS  when fixed
+EXTRA_OECONF = " --without-tcl --without-qt --without-pam --without-dbus"
+
+PACKAGES_prepend = "libuniconf libuniconf-dbg "
+PACKAGES_prepend = "uniconfd uniconfd-dbg "
+PACKAGES_prepend = "libwvstreams-base libwvstreams-base-dbg "
+PACKAGES_prepend = "libwvstreams-extras libwvstreams-extras-dbg "
+
+FILES_libuniconf     = "${libdir}/libuniconf.so.*"
+FILES_libuniconf-dbg = "${libdir}/.debug/libuniconf.so.*"
+
+FILES_uniconfd     = "${sbindir}/uniconfd ${sysconfdir}/uniconf.conf ${localstatedir}/uniconf"
+FILES_uniconfd-dbg = "${sbindir}/.debug/uniconfd"
+
+FILES_libwvstreams-base     = "${libdir}/libwvutils.so.*"
+FILES_libwvstreams-base-dbg = "${libdir}/.debug/libwvutils.so.*"
+
+FILES_libwvstreams-extras     = "${libdir}/libwvbase.so.* ${libdir}/libwvstreams.so.*"
+FILES_libwvstreams-extras-dbg = "${libdir}/.debug/libwvbase.so.* ${libdir}/.debug/libwvstreams.so.*"
+
+PARALLEL_MAKE = ""
+
+do_configure() {
+        autoreconf
+        oe_runconf
+}
+
+SRC_URI[md5sum] = "2760dac31a43d452a19a3147bfde571c"
+SRC_URI[sha256sum] = "8403f5fbf83aa9ac0c6ce15d97fd85607488152aa84e007b7d0621b8ebc07633"
-- 
1.7.1

Re: [PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Koen Kooi]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

On 25-04-11 11:57, Søren Holm wrote:

> +LICENSE = "LGPL"

That needs a version number, e.g. LGPLv2.1

> +DEPENDS = "zlib openssl (>= 0.9.8)"

There's no < 0.9.8 in the tree anymore

> +# dbus detection currently broken in configure.ac; remember to add "dbus (>= 1.2.14)" to DEPENDS  when fixed

has it been fixed?

> +EXTRA_OECONF = " --without-tcl --without-qt --without-pam --without-dbus"

The pam stuff needs to be converted into something like:

DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"

${@base_contains('DISTRO_FEATURES', 'pam', '--with-pam',
'--without-pam', d)}

> +
> +PACKAGES_prepend = "libuniconf libuniconf-dbg "
> +PACKAGES_prepend = "uniconfd uniconfd-dbg "
> +PACKAGES_prepend = "libwvstreams-base libwvstreams-base-dbg "
> +PACKAGES_prepend = "libwvstreams-extras libwvstreams-extras-dbg "

Change that to a single PACKAGES =+


> +do_configure() {
> +        autoreconf
> +        oe_runconf
> +}

Why not stock autotools_do_configure?

regards,

Koen

-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (Darwin)

iD8DBQFNtUdGMkyGM64RGpERAsajAJ9nepgViPPFhbWwsS2AchhCw/tlBACfbVUa
JdSqbThI5m5aFsEd0cajYB4=
=gUZN
-----END PGP SIGNATURE-----

Re: [PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Søren Holm]

I will edit the recipe a bit. It is just a copy of the 4.6.0 recipe.

Mandag den 25. april 2011 12:04:54 skrev Koen Kooi:
> On 25-04-11 11:57, Søren Holm wrote:
> 
> > +LICENSE = "LGPL"
> 
> That needs a version number, e.g. LGPLv2.1
> 
> > +DEPENDS = "zlib openssl (>= 0.9.8)"
> 
> There's no < 0.9.8 in the tree anymore
> 
> > +# dbus detection currently broken in configure.ac; remember to add "dbus (>= 1.2.14)" to DEPENDS  when fixed
> 
> has it been fixed?
> 
> > +EXTRA_OECONF = " --without-tcl --without-qt --without-pam --without-dbus"
> 
> The pam stuff needs to be converted into something like:
> 
> DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
> 
> ${@base_contains('DISTRO_FEATURES', 'pam', '--with-pam',
> '--without-pam', d)}
> 
> > +
> > +PACKAGES_prepend = "libuniconf libuniconf-dbg "
> > +PACKAGES_prepend = "uniconfd uniconfd-dbg "
> > +PACKAGES_prepend = "libwvstreams-base libwvstreams-base-dbg "
> > +PACKAGES_prepend = "libwvstreams-extras libwvstreams-extras-dbg "
> 
> Change that to a single PACKAGES =+
> 
> 
> > +do_configure() {
> > +        autoreconf
> > +        oe_runconf
> > +}
> 
> Why not stock autotools_do_configure?
> 

Re: [PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Paul Menzel]

[-- Attachment #1: Type: text/plain, Size: 975 bytes --]

Am Montag, den 25.04.2011, 12:29 +0200 schrieb Søren Holm:
> I will edit the recipe a bit. It is just a copy of the 4.6.0 recipe.

Please pass `-M -C -C` to `git format-patch` next time, so that copies
or renames are detected.

Please also add what build configurations you used for testing next
time. I have build 4.6.1 successfully in several configurations and I
pushed your patch [1].

Please update the patch queue [2] using the Web interface or the
following command.

	$ pwclient update -s Accepted -c aaf30cc3e147816c63e694ef65951b3cd2dc48c5 2815

Your earlier message was also recorded, so you could do something like
the following.

	$ pwclient update -s Superseded 2813

Please post a follow up patch (in a new thread) addressing the things
Koen pointed out.


Thanks,

Paul


[1] http://cgit.openembedded.org/cgit.cgi/openembedded/commit/?id=aaf30cc3e147816c63e694ef65951b3cd2dc48c5
[2] http://openembedded.org/index.php/Patchwork

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

Re: [PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Søren Holm]

Is there a document describing the workflow around patchwork?
I'm a bit lost as to how it is supposed to work.

Mandag den 25. april 2011 16:55:29 skrev Paul Menzel:
> Am Montag, den 25.04.2011, 12:29 +0200 schrieb Søren Holm:
> > I will edit the recipe a bit. It is just a copy of the 4.6.0 recipe.
> 
> Please pass `-M -C -C` to `git format-patch` next time, so that copies
> or renames are detected.
> 
> Please also add what build configurations you used for testing next
> time. I have build 4.6.1 successfully in several configurations and I
> pushed your patch [1].
> 
> Please update the patch queue [2] using the Web interface or the
> following command.
> 
> 	$ pwclient update -s Accepted -c aaf30cc3e147816c63e694ef65951b3cd2dc48c5 2815
> 
> Your earlier message was also recorded, so you could do something like
> the following.
> 
> 	$ pwclient update -s Superseded 2813
> 
> Please post a follow up patch (in a new thread) addressing the things
> Koen pointed out.
> 

Re: [PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Paul Menzel]

[-- Attachment #1: Type: text/plain, Size: 889 bytes --]

Am Montag, den 25.04.2011, 21:34 +0200 schrieb Søren Holm:
> Is there a document describing the workflow around patchwork?

I am not sure. There is only the Wiki page in OpenEmbedded [1]. Here is
a small summary.

1. An email address for Patchwork is subscribed to openembedded-devel. A
filter searches for patches send to the list and adds it to the patch
queue.
2. The state of these patches is tracked in a database and people need
to update the default state NEW to the current one.
3. Edits can be done after registration using the Web interface or the
command line tool `pwclient`.

> I'm a bit lost as to how it is supposed to work.

Sadly, only the patch submitters are allowed to change the states in the
patch queue. Therefore the submitters have to update the state of their
patches.


Thanks,

Paul


[1] http://openembedded.org/index.php/Patchwork

[-- Attachment #2: This is a digitally signed message part --]
[-- Type: application/pgp-signature, Size: 205 bytes --]

[PATCH] wvstreams: Added recipe for wxstreams 4.6.1.

[Søren Holm]

Signed-off-by: Søren Holm <sgh@sgh.dk>
---
 recipes/wvstreams/wvstreams_4.6.1.bb |   44 ++++++++++++++++++++++++++++++++++
 1 files changed, 44 insertions(+), 0 deletions(-)
 create mode 100644 recipes/wvstreams/wvstreams_4.6.1.bb

diff --git a/recipes/wvstreams/wvstreams_4.6.1.bb b/recipes/wvstreams/wvstreams_4.6.1.bb
new file mode 100644
index 0000000..b11b500
--- /dev/null
+++ b/recipes/wvstreams/wvstreams_4.6.1.bb
@@ -0,0 +1,44 @@
+HOMEPAGE = "http://alumnit.ca/wiki/index.php?page=WvStreams"
+LICENSE = "LGPL"
+DESCRIPTION = "WvStreams is a network programming library in C++"
+DEPENDS = "zlib openssl (>= 0.9.8)"
+
+PR = "r1"
+
+SRC_URI = "http://wvstreams.googlecode.com/files/${PN}-${PV}.tar.gz \
+	file://0001-Fixed-missing-header-includes.patch \
+	"
+
+inherit autotools pkgconfig
+
+LDFLAGS_append = " -Wl,-rpath-link,${TOOLCHAIN_PATH}/${TARGET_SYS}/lib"
+
+# dbus detection currently broken in configure.ac; remember to add "dbus (>= 1.2.14)" to DEPENDS  when fixed
+EXTRA_OECONF = " --without-tcl --without-qt --without-pam --without-dbus"
+
+PACKAGES_prepend = "libuniconf libuniconf-dbg "
+PACKAGES_prepend = "uniconfd uniconfd-dbg "
+PACKAGES_prepend = "libwvstreams-base libwvstreams-base-dbg "
+PACKAGES_prepend = "libwvstreams-extras libwvstreams-extras-dbg "
+
+FILES_libuniconf     = "${libdir}/libuniconf.so.*"
+FILES_libuniconf-dbg = "${libdir}/.debug/libuniconf.so.*"
+
+FILES_uniconfd     = "${sbindir}/uniconfd ${sysconfdir}/uniconf.conf ${localstatedir}/uniconf"
+FILES_uniconfd-dbg = "${sbindir}/.debug/uniconfd"
+
+FILES_libwvstreams-base     = "${libdir}/libwvutils.so.*"
+FILES_libwvstreams-base-dbg = "${libdir}/.debug/libwvutils.so.*"
+
+FILES_libwvstreams-extras     = "${libdir}/libwvbase.so.* ${libdir}/libwvstreams.so.*"
+FILES_libwvstreams-extras-dbg = "${libdir}/.debug/libwvbase.so.* ${libdir}/.debug/libwvstreams.so.*"
+
+PARALLEL_MAKE = ""
+
+do_configure() {
+        autoreconf
+        oe_runconf
+}
+
+SRC_URI[md5sum] = "2760dac31a43d452a19a3147bfde571c"
+SRC_URI[sha256sum] = "8403f5fbf83aa9ac0c6ce15d97fd85607488152aa84e007b7d0621b8ebc07633"
-- 
1.7.1