[PATCH 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[PATCH 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Matthew McClintock]

Signed-off-by: Matthew McClintock <msm@freescale.com>
---
 meta/recipes-devtools/strace/strace_4.5.20.bb |    8 ++++++--
 1 files changed, 6 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-devtools/strace/strace_4.5.20.bb b/meta/recipes-devtools/strace/strace_4.5.20.bb
index b3d2aa5..0e22657 100644
--- a/meta/recipes-devtools/strace/strace_4.5.20.bb
+++ b/meta/recipes-devtools/strace/strace_4.5.20.bb
@@ -3,9 +3,13 @@ HOMEPAGE = "http://strace.sourceforge.net"
 SECTION = "console/utils"
 LICENSE = "BSD"
 LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=4535377ede62550fdeaf39f595fd550a"
-PR = "r2"
+PR = "r3"
+
+PACKAGES = "${PN} ${PN}-graph"
+FILES_${PN} = "${bindir}/strace"
+FILES_${PN}-graph = "${bindir}/strace-graph"
+RDEPENDS_${PN}-graph = "perl"
 
-RDEPENDS = "perl"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.bz2 \
            file://sigmask.patch \
-- 
1.7.6.1

[PATCH 2/2] Add new util-linux-chkdupexe package to avoid making perl a dependecy for all of util-linux

[Matthew McClintock]

Signed-off-by: Matthew McClintock <msm@freescale.com>
---
 meta/recipes-core/util-linux/util-linux.inc       |    7 +++++--
 meta/recipes-core/util-linux/util-linux_2.19.1.bb |    2 +-
 2 files changed, 6 insertions(+), 3 deletions(-)

diff --git a/meta/recipes-core/util-linux/util-linux.inc b/meta/recipes-core/util-linux/util-linux.inc
index 67d81b9..eeba67c 100644
--- a/meta/recipes-core/util-linux/util-linux.inc
+++ b/meta/recipes-core/util-linux/util-linux.inc
@@ -29,7 +29,8 @@ PACKAGES =+ "util-linux-agetty util-linux-fdisk util-linux-cfdisk util-linux-sfd
              util-linux-swaponoff util-linux-losetup util-linux-umount \
              util-linux-mount util-linux-readprofile util-linux-libblkid \
              util-linux-libblkid-dev util-linux-libuuid util-linux-libuuid-dev \
-             util-linux-uuidgen util-linux-lscpu util-linux-fsck util-linux-blkid"
+             util-linux-uuidgen util-linux-lscpu util-linux-fsck util-linux-blkid \
+	     util-linux-chkdupexe"
 
 EXTRA_OECONF = "--disable-use-tty-group --disable-makeinstall-chown --enable-elvtune --enable-init --enable-kill --enable-last \
  --enable-mesg --enable-partx --enable-raw --enable-rdev --enable-reset \
@@ -55,6 +56,7 @@ FILES_util-linux-libuuid-dev = "${libdir}/libuuid.so ${libdir}/libuuid.a ${libdi
 FILES_util-linux-lscpu = "${bindir}/lscpu"
 
 FILES_util-linux-fsck = "${base_sbindir}/fsck*"
+FILES_util-linux-chkdupexe = "${bindir}/chkdupexe"
 
 # Util-linux' blkid replaces the e2fsprogs one
 FILES_util-linux-blkid = "${base_sbindir}/blkid*"
@@ -62,7 +64,8 @@ RCONFLICTS_util-linux-blkid = "e2fsprogs-blkid"
 RREPLACES_util-linux-blkid = "e2fsprogs-blkid"
 
 RRECOMMENDS_${PN} = "util-linux-fdisk util-linux-cfdisk util-linux-sfdisk util-linux-mount util-linux-readprofile "
-RDEPENDS_${PN} = "util-linux-umount util-linux-swaponoff util-linux-losetup perl"
+RDEPENDS_${PN} = "util-linux-umount util-linux-swaponoff util-linux-losetup"
+RDEPENDS_${PN}-chkdupexe = "perl"
 
 RRECOMMENDS_${PN}_virtclass-native = ""
 RDEPENDS_${PN}_virtclass-native = ""
diff --git a/meta/recipes-core/util-linux/util-linux_2.19.1.bb b/meta/recipes-core/util-linux/util-linux_2.19.1.bb
index 04f4457..fb5637e 100644
--- a/meta/recipes-core/util-linux/util-linux_2.19.1.bb
+++ b/meta/recipes-core/util-linux/util-linux_2.19.1.bb
@@ -1,5 +1,5 @@
 MAJOR_VERSION = "2.19"
-PR = "r8"
+PR = "r9"
 require util-linux.inc
 
 # note that `lscpu' is under GPLv3+
-- 
1.7.6.1

Re: [PATCH 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Richard Purdie]

On Thu, 2011-10-27 at 00:14 -0500, Matthew McClintock wrote:
> Signed-off-by: Matthew McClintock <msm@freescale.com>
> ---
>  meta/recipes-devtools/strace/strace_4.5.20.bb |    8 ++++++--
>  1 files changed, 6 insertions(+), 2 deletions(-)
> 
> diff --git a/meta/recipes-devtools/strace/strace_4.5.20.bb b/meta/recipes-devtools/strace/strace_4.5.20.bb
> index b3d2aa5..0e22657 100644
> --- a/meta/recipes-devtools/strace/strace_4.5.20.bb
> +++ b/meta/recipes-devtools/strace/strace_4.5.20.bb
> @@ -3,9 +3,13 @@ HOMEPAGE = "http://strace.sourceforge.net"
>  SECTION = "console/utils"
>  LICENSE = "BSD"
>  LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=4535377ede62550fdeaf39f595fd550a"
> -PR = "r2"
> +PR = "r3"
> +
> +PACKAGES = "${PN} ${PN}-graph"
> +FILES_${PN} = "${bindir}/strace"
> +FILES_${PN}-graph = "${bindir}/strace-graph"
> +RDEPENDS_${PN}-graph = "perl"
>  
This wipes out the ${PN}-dbg, ${PN}-dev and other packages. You need to
add ${PN}-graph to PACKAGES rather than overwriting it.

Cheers,

Richard

Re: [PATCH 2/2] Add new util-linux-chkdupexe package to avoid making perl a dependecy for all of util-linux

[Richard Purdie]

On Thu, 2011-10-27 at 00:14 -0500, Matthew McClintock wrote:
> Signed-off-by: Matthew McClintock <msm@freescale.com>
> ---
>  meta/recipes-core/util-linux/util-linux.inc       |    7 +++++--
>  meta/recipes-core/util-linux/util-linux_2.19.1.bb |    2 +-
>  2 files changed, 6 insertions(+), 3 deletions(-)

Merged to master, thanks.

Cheers,

Richard

[PATCH v2 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Matthew McClintock]

Signed-off-by: Matthew McClintock <msm@freescale.com>
---
v2: Change to use PACKAGES_prepend instead of explictly listing all packages
and also fixing the fact we missed the -dev and -dbg packages before

 meta/recipes-devtools/strace/strace_4.5.20.bb |    4 +++-
 1 files changed, 3 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-devtools/strace/strace_4.5.20.bb b/meta/recipes-devtools/strace/strace_4.5.20.bb
index b3d2aa5..450abea 100644
--- a/meta/recipes-devtools/strace/strace_4.5.20.bb
+++ b/meta/recipes-devtools/strace/strace_4.5.20.bb
@@ -5,7 +5,9 @@ LICENSE = "BSD"
 LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=4535377ede62550fdeaf39f595fd550a"
 PR = "r2"
 
-RDEPENDS = "perl"
+PACKAGES_prepend = "${PN}-graph "
+FILES_${PN}-graph = "${bindir}/strace-graph"
+RDEPENDS_${PN}-graph = "perl"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.bz2 \
            file://sigmask.patch \
-- 
1.7.6.1

Re: [PATCH v2 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Richard Purdie]

On Thu, 2011-10-27 at 14:31 -0500, Matthew McClintock wrote:
> Signed-off-by: Matthew McClintock <msm@freescale.com>
> ---
> v2: Change to use PACKAGES_prepend instead of explictly listing all packages
> and also fixing the fact we missed the -dev and -dbg packages before
> 
>  meta/recipes-devtools/strace/strace_4.5.20.bb |    4 +++-
>  1 files changed, 3 insertions(+), 1 deletions(-)
> 
> diff --git a/meta/recipes-devtools/strace/strace_4.5.20.bb b/meta/recipes-devtools/strace/strace_4.5.20.bb
> index b3d2aa5..450abea 100644
> --- a/meta/recipes-devtools/strace/strace_4.5.20.bb
> +++ b/meta/recipes-devtools/strace/strace_4.5.20.bb
> @@ -5,7 +5,9 @@ LICENSE = "BSD"
>  LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=4535377ede62550fdeaf39f595fd550a"
>  PR = "r2"
>  
> -RDEPENDS = "perl"
> +PACKAGES_prepend = "${PN}-graph "
> +FILES_${PN}-graph = "${bindir}/strace-graph"
> +RDEPENDS_${PN}-graph = "perl"

I should have been clearer in my original email, pretty much every other
recipe uses += or =+ in this context. Whilst the _prepend override is
probably ok, its probably a bit heavy in this case and the standard
operator should work just fine.

Cheers,

Richard

Re: [PATCH v2 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[McClintock Matthew-B29882]

On Fri, Oct 28, 2011 at 3:55 AM, Richard Purdie
<richard.purdie@linuxfoundation.org> wrote:
>> -RDEPENDS = "perl"
>> +PACKAGES_prepend = "${PN}-graph "
>> +FILES_${PN}-graph = "${bindir}/strace-graph"
>> +RDEPENDS_${PN}-graph = "perl"
>
> I should have been clearer in my original email, pretty much every other
> recipe uses += or =+ in this context. Whilst the _prepend override is
> probably ok, its probably a bit heavy in this case and the standard
> operator should work just fine.

usr/bin/strace-graph will be picked up by the default rules for ${PN}
- by prepending I thought I was letting strace-graph get picked out
first in ${PN}-graph then everything else could go in ${PN} without
having the explicitly list a new rule for ${PN}.

-M

Re: [PATCH v2 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Phil Blundell]

On Fri, 2011-10-28 at 15:34 +0000, McClintock Matthew-B29882 wrote:
> On Fri, Oct 28, 2011 at 3:55 AM, Richard Purdie
> <richard.purdie@linuxfoundation.org> wrote:
> >> -RDEPENDS = "perl"
> >> +PACKAGES_prepend = "${PN}-graph "
> >> +FILES_${PN}-graph = "${bindir}/strace-graph"
> >> +RDEPENDS_${PN}-graph = "perl"
> >
> > I should have been clearer in my original email, pretty much every other
> > recipe uses += or =+ in this context. Whilst the _prepend override is
> > probably ok, its probably a bit heavy in this case and the standard
> > operator should work just fine.
> 
> usr/bin/strace-graph will be picked up by the default rules for ${PN}
> - by prepending I thought I was letting strace-graph get picked out
> first in ${PN}-graph then everything else could go in ${PN} without
> having the explicitly list a new rule for ${PN}.

That logic sounds reasonable, but I think Richard's point was that it's
more conventional to use "=+" rather than an override for prepending.

p.

Re: [PATCH v2 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[McClintock Matthew-B29882]

On Fri, Oct 28, 2011 at 10:54 AM, Phil Blundell <philb@gnu.org> wrote:
> That logic sounds reasonable, but I think Richard's point was that it's
> more conventional to use "=+" rather than an override for prepending.

I sort of forgot that += and =+ are different. Shall I resubmit this patch?

-M

Re: [PATCH v2 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Paul Eggleton]

On Friday 28 October 2011 21:07:44 McClintock Matthew-B29882 wrote:
> On Fri, Oct 28, 2011 at 10:54 AM, Phil Blundell <philb@gnu.org> wrote:
> > That logic sounds reasonable, but I think Richard's point was that it's
> > more conventional to use "=+" rather than an override for prepending.
> 
> I sort of forgot that += and =+ are different. Shall I resubmit this patch?

Yes please.

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

[PATCH v3 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Matthew McClintock]

Signed-off-by: Matthew McClintock <msm@freescale.com>
---
v2: Change to use PACKAGES_prepend instead of explictly listing all packages
and also fixing the fact we missed the -dev and -dbg packages before

v3: Use += instead of _prepend to add strace-graph packages

 meta/recipes-devtools/strace/strace_4.5.20.bb |    4 +++-
 1 files changed, 3 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-devtools/strace/strace_4.5.20.bb b/meta/recipes-devtools/strace/strace_4.5.20.bb
index b3d2aa5..53df067 100644
--- a/meta/recipes-devtools/strace/strace_4.5.20.bb
+++ b/meta/recipes-devtools/strace/strace_4.5.20.bb
@@ -5,7 +5,9 @@ LICENSE = "BSD"
 LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=4535377ede62550fdeaf39f595fd550a"
 PR = "r2"
 
-RDEPENDS = "perl"
+PACKAGES =+ "${PN}-graph "
+FILES_${PN}-graph = "${bindir}/strace-graph"
+RDEPENDS_${PN}-graph = "perl"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.bz2 \
            file://sigmask.patch \
-- 
1.7.6.1

Re: [PATCH v3 1/2] Add new strace-graph package to avoid making perl a dependecy for all of strace

[Saul Wold]

On 10/31/2011 09:26 AM, Matthew McClintock wrote:
> Signed-off-by: Matthew McClintock<msm@freescale.com>
> ---
> v2: Change to use PACKAGES_prepend instead of explictly listing all packages
> and also fixing the fact we missed the -dev and -dbg packages before
>
> v3: Use += instead of _prepend to add strace-graph packages
>
>   meta/recipes-devtools/strace/strace_4.5.20.bb |    4 +++-
>   1 files changed, 3 insertions(+), 1 deletions(-)
>
> diff --git a/meta/recipes-devtools/strace/strace_4.5.20.bb b/meta/recipes-devtools/strace/strace_4.5.20.bb
> index b3d2aa5..53df067 100644
> --- a/meta/recipes-devtools/strace/strace_4.5.20.bb
> +++ b/meta/recipes-devtools/strace/strace_4.5.20.bb
> @@ -5,7 +5,9 @@ LICENSE = "BSD"
>   LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=4535377ede62550fdeaf39f595fd550a"
>   PR = "r2"
>
> -RDEPENDS = "perl"
> +PACKAGES =+ "${PN}-graph "
> +FILES_${PN}-graph = "${bindir}/strace-graph"
> +RDEPENDS_${PN}-graph = "perl"
>
>   SRC_URI = "${SOURCEFORGE_MIRROR}/strace/strace-${PV}.tar.bz2 \
>              file://sigmask.patch \

Merged into OE-Core

Thanks
	Sau!