[meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[nitin.a.kamble]

From: Nitin A Kamble <nitin.a.kamble@intel.com>

This commits are for meta-intel layer. And Ross'es patch tries to achieve the same 
from the oecore layer.

Thanks,
Nitin


The following changes since commit 154156a4db56f7b33fb1765cf6b87e683d027af9:

  emgd-driver-bin: add further needed soft links (2012-11-26 18:02:11 -0600)

are available in the git repository at:
  git://git.yoctoproject.org/meta-intel-contrib nitin/misc
  http://git.yoctoproject.org/cgit.cgi/meta-intel-contrib/log/?h=nitin/misc

Nitin A Kamble (3):
  xserver-xorg-1.9.3: fix packaging issues
  xserver-psb: fix packaging issues
  xserver-xorg-video-psb: fix packaging issues

 .../xorg-xserver/xserver-xorg-1.9.3.inc            |    2 +-
 .../recipes-graphics/xorg-xserver/xserver-xorg.inc |  160 ++++++++++++++++++++
 .../xorg-xserver/xserver-xorg_1.9.3.bb             |    2 +-
 conf/machine/include/meta-intel.inc                |   10 +-
 .../xorg-xserver/xserver-psb-1.7.99.2.inc          |    2 +-
 .../xorg-xserver/xserver-psb_1.7.99.2.bb           |    2 +-
 .../xserver-xorg-video-psb_0.32.1.bb               |    8 +-
 7 files changed, 180 insertions(+), 6 deletions(-)
 create mode 100644 common/recipes-graphics/xorg-xserver/xserver-xorg.inc

-- 
1.7.3.4

[meta-intel patch 1/3] xserver-xorg-1.9.3: fix packaging issues

[nitin.a.kamble]

From: Nitin A Kamble <nitin.a.kamble@intel.com>

This was affecting crownbay BSP. And it may also be affecting
fri2, sys940x BSPs. And this commit will fix the issues for all
these EMGD based BSPs.

Because of the xserver recipe upgrade in the oecore layer, the
xserver packaging defined in the .inc file is changed. And this
change breaks the packaging of this older xserver recipe.
  This commit fixes the issue by using meta-intel layer specific
version of xserver-xorg.inc file

This fixes bug:
[Yocto #3502]

All these warnings are also fixed with this commit:

WARNING: QA Issue: xserver-psb: Files/directories were installed but not shipped
  /usr/lib/xorg/modules/extensions/libextmod.so
  /usr/lib/xorg/modules/extensions/libdbe.so
  /usr/lib/xorg/modules/extensions/libdri.so
  /usr/lib/xorg/modules/extensions/libdri2.so
  /usr/lib/xorg/modules/linux/libfbdevhw.so

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>
---
 .../xorg-xserver/xserver-xorg-1.9.3.inc            |    2 +-
 .../recipes-graphics/xorg-xserver/xserver-xorg.inc |  160 ++++++++++++++++++++
 .../xorg-xserver/xserver-xorg_1.9.3.bb             |    2 +-
 conf/machine/include/meta-intel.inc                |   10 +-
 4 files changed, 171 insertions(+), 3 deletions(-)
 create mode 100644 common/recipes-graphics/xorg-xserver/xserver-xorg.inc

diff --git a/common/recipes-graphics/xorg-xserver/xserver-xorg-1.9.3.inc b/common/recipes-graphics/xorg-xserver/xserver-xorg-1.9.3.inc
index 1c71d7b..39c9c92 100644
--- a/common/recipes-graphics/xorg-xserver/xserver-xorg-1.9.3.inc
+++ b/common/recipes-graphics/xorg-xserver/xserver-xorg-1.9.3.inc
@@ -17,4 +17,4 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=3dd2bbe3563837f80ed8926b06c1c353"
 SRC_URI[md5sum] = "5bef6839a76d029204ab31aa2fcb5201"
 SRC_URI[sha256sum] = "864831f51e841ff37f2445d1c85b86b559c8860a435fb496aead4f256a2b141d"
 
-PR = "r2"
+PR = "r3"
diff --git a/common/recipes-graphics/xorg-xserver/xserver-xorg.inc b/common/recipes-graphics/xorg-xserver/xserver-xorg.inc
new file mode 100644
index 0000000..49b9b46
--- /dev/null
+++ b/common/recipes-graphics/xorg-xserver/xserver-xorg.inc
@@ -0,0 +1,160 @@
+DESCRIPTION = "The X.Org X server"
+HOMEPAGE = "http://www.x.org"
+SECTION = "x11/base"
+LICENSE = "MIT-X"
+
+# xf86-*-* packages depend on an X server built with the xfree86 DDX
+# so we have a virtual to represent that:
+# deprecated, we should use virtual/xserver instead
+PROVIDES = "virtual/xserver-xf86"
+
+# Other packages tend to just care that there is *an* X server:
+PROVIDES += "virtual/xserver"
+
+PE = "2"
+INC_PR = "r3"
+
+XORG_PN = "xorg-server"
+SRC_URI = "${XORG_MIRROR}/individual/xserver/${XORG_PN}-${PV}.tar.bz2"
+SRC_URI += "file://macro_tweak.patch"
+
+S = "${WORKDIR}/${XORG_PN}-${PV}"
+
+inherit autotools pkgconfig
+
+PROTO_DEPS = "randrproto renderproto fixesproto damageproto xextproto xproto xf86dgaproto xf86miscproto xf86vidmodeproto compositeproto recordproto resourceproto videoproto scrnsaverproto  xineramaproto fontsproto kbproto inputproto bigreqsproto xcmiscproto glproto"
+LIB_DEPS = "pixman libxfont xtrans libxau libxext libxdmcp libdrm libxkbfile libpciaccess openssl"
+DEPENDS = "${PROTO_DEPS} ${LIB_DEPS} font-util"
+
+# Split out some modules and extensions from the main package
+# These aren't needed for basic operations and only take up space:
+#  32.0k   libdri.so
+#  91.0k   libexa.so
+#  336.0k  libglx.so
+#  1360k   libint10.so
+#  180.0k  libwfb.so
+#  320.0k  libxaa.so
+#  124.0k  libxf1bpp.so
+#  84.0k   libxf4bpp.so
+#          librecord.so
+#          libextmod.so
+#          libdbe.so
+
+PACKAGES =+ "${PN}-security-policy \
+             ${PN}-sdl \
+             ${PN}-fbdev \
+             ${PN}-xvfb \
+             ${PN}-utils \
+             ${PN}-xephyr \
+             ${PN}-multimedia-modules \
+             ${PN}-extension-dri \
+             ${PN}-extension-dri2 \
+             ${PN}-extension-glx \
+             ${PN}-extension-record \
+             ${PN}-extension-extmod \
+             ${PN}-extension-dbe \
+             ${PN}-extension-fbdevhw \
+             ${PN}-module-libint10 \
+             ${PN}-module-libafb \
+             ${PN}-module-libwfb  \
+             ${PN}-module-libmfb \
+             ${PN}-module-libcfb \
+             ${PN}-module-exa \
+             ${PN}-module-xaa \
+             ${PN}-module-libxf1bpp \
+             ${PN}-module-libxf4bpp"
+
+RRECOMMENDS_${PN} += "${PN}-security-policy xkeyboard-config rgb xserver-xf86-config"
+RDEPENDS_${PN}-xvfb += "xkeyboard-config"
+RDEPENDS_${PN}-module-exa = "${PN} (= ${EXTENDPKGV})"
+
+FILES_${PN} = "${bindir} ${libdir}/X11/Options ${libdir}/X11/Cards ${libdir}/X11/getconfig ${libdir}/X11/etc ${libdir}/modules/*.so ${libdir}/xorg/modules/*.so /etc/X11 ${libdir}/xorg/protocol.txt ${datadir}/X11/xorg.conf.d"
+FILES_${PN}-dev += "${libdir}/xorg/modules/*.la ${libdir}/xorg/modules/*/*.la"
+FILES_${PN}-doc += "${libdir}/X11/doc ${datadir}/X11/xkb/compiled/README.compiled ${localstatedir}/lib/xkb/README.compiled"
+FILES_${PN}-dbg += "${libdir}/xorg/modules/.debug \
+                    ${libdir}/xorg/modules/*/.debug \
+                    ${libdir}/xorg/modules/*/*/.debug \
+                    "
+FILES_${PN}-security-policy += "${libdir}/xserver/SecurityPolicy"
+FILES_${PN}-sdl = "${bindir}/Xsdl"
+FILES_${PN}-fbdev = "${bindir}/Xfbdev"
+FILES_${PN}-xvfb = "${bindir}/Xvfb"
+FILES_${PN}-utils = "${bindir}/scanpci ${bindir}/pcitweak ${bindir}/ioport ${bindir}/in[bwl] ${bindir}/out[bwl] ${bindir}/mmap[rw] ${bindir}/gtf ${bindir}/getconfig ${bindir}/getconfig.pl"
+FILES_${PN}-xephyr = "${bindir}/Xephyr"
+FILES_${PN}-multimedia-modules = "${libdir}/xorg/modules/multimedia/*drv*"
+FILES_${PN}-extension-dri = "${libdir}/xorg/modules/extensions/libdri.so"
+FILES_${PN}-extension-dri2 = "${libdir}/xorg/modules/extensions/libdri2.so"
+FILES_${PN}-extension-glx = "${libdir}/xorg/modules/extensions/libglx.so"
+FILES_${PN}-extension-record = "${libdir}/xorg/modules/extensions/librecord.so"
+FILES_${PN}-extension-extmod = "${libdir}/xorg/modules/extensions/libextmod.so"
+FILES_${PN}-extension-dbe = "${libdir}/xorg/modules/extensions/libdbe.so"
+FILES_${PN}-extension-fbdevhw = "${libdir}/xorg/modules/linux/libfbdevhw.so"
+FILES_${PN}-module-libint10 = "${libdir}/xorg/modules/libint10.so"
+FILES_${PN}-module-libafb = "${libdir}/xorg/modules/libafb.so"
+FILES_${PN}-module-libwfb = "${libdir}/xorg/modules/libwfb.so"
+FILES_${PN}-module-libmfb = "${libdir}/xorg/modules/libmfb.so"
+FILES_${PN}-module-libcfb = "${libdir}/xorg/modules/libcfb.so"
+FILES_${PN}-module-exa = "${libdir}/xorg/modules/libexa.so"
+FILES_${PN}-module-xaa = "${libdir}/xorg/modules/libxaa.so"
+FILES_${PN}-module-libxf1bpp = "${libdir}/xorg/modules/libxf1bpp.so"
+FILES_${PN}-module-libxf4bpp = "${libdir}/xorg/modules/libxf4bpp.so"
+
+EXTRA_OECONF += "--with-fop=no \
+                 --without-xmlto \
+                 --with-pic \
+                 --disable-static \
+                 --disable-acfb \
+                 --disable-ccfb \
+                 --disable-mcfb \
+                 --disable-xinerama \
+                 --disable-xf86misc \
+                 --disable-xorgcfg \
+                 --disable-record \
+                 --disable-dmx \
+                 --disable-xnest \
+                 --disable-xvfb \
+                 --enable-composite \
+                 --without-dtrace \
+                 --with-int10=x86emu \
+                 --sysconfdir=/etc/X11 \
+                 --localstatedir=/var \
+                 --with-fontdir=${datadir}/fonts/X11 \
+                 --with-xkb-output=/var/lib/xkb \
+                 ac_cv_file__usr_share_sgml_X11_defs_ent=no \
+"
+
+PACKAGECONFIG ??= "udev ${@base_contains('DISTRO_FEATURES', 'opengl', 'glx', '', d)}"
+PACKAGECONFIG[udev] = "--enable-config-udev,--disable-config-udev,udev"
+PACKAGECONFIG[glx] = "--enable-dri --enable-dri2 --enable-glx --enable-glx-tls,\
+                      --disable-dri --disable-glx,\
+                      xf86driproto dri2proto mesa-dri"
+
+do_install_append () {
+	# Its assumed base-files creates this for us
+	rmdir ${D}${localstatedir}/log/
+}
+
+# Add runtime provides for the ABI versions of the video and input subsystems,
+# so that drivers can depend on the relevant version.
+python populate_packages_prepend() {
+    import subprocess
+
+    # Set PKG_CONFIG_PATH so pkg-config looks at the .pc files that are going
+    # into the new package, not the staged ones.
+    newenv = dict(os.environ)
+    newenv["PKG_CONFIG_PATH"] = d.expand("${PKGD}${libdir}/pkgconfig/")
+
+    def get_abi(name):
+        abis = {
+          "video": "abi_videodrv",
+          "input": "abi_xinput"
+        }
+        p = subprocess.Popen(args="pkg-config --variable=%s xorg-server" % abis[name],
+                             shell=True, env=newenv, stdout=subprocess.PIPE)
+        output = p.communicate()[0]
+        return "xorg-abi-%s-%s" % (name, output.split(".")[0])
+
+    pn = d.getVar("PN", True)
+    d.appendVar("RPROVIDES_" + pn, " " + get_abi("input"))
+    d.appendVar("RPROVIDES_" + pn, " " + get_abi("video"))
+}
diff --git a/common/recipes-graphics/xorg-xserver/xserver-xorg_1.9.3.bb b/common/recipes-graphics/xorg-xserver/xserver-xorg_1.9.3.bb
index f62cad2..8e97888 100644
--- a/common/recipes-graphics/xorg-xserver/xserver-xorg_1.9.3.bb
+++ b/common/recipes-graphics/xorg-xserver/xserver-xorg_1.9.3.bb
@@ -1,4 +1,4 @@
-require recipes-graphics/xorg-xserver/xserver-xorg.inc
+require xserver-xorg.inc
 require xserver-xorg-${PV}.inc
 
 PE = "1"
diff --git a/conf/machine/include/meta-intel.inc b/conf/machine/include/meta-intel.inc
index f0e538d..ed3a423 100644
--- a/conf/machine/include/meta-intel.inc
+++ b/conf/machine/include/meta-intel.inc
@@ -7,10 +7,18 @@
 #
 # XSERVER subcomponents, used to build the XSERVER variable
 #
+
+# for Xserver older than 1.13.0
+OLD_XSERVER_IA32_EXT = "xserver-xorg-extension-dri \
+           xserver-xorg-extension-dri2 \
+           xserver-xorg-extension-extmod \
+           xserver-xorg-extension-dbe \
+           "
+
 XSERVER_IA32_EMGD = "emgd-driver-bin \
+           ${OLD_XSERVER_IA32_EXT} \
            "
 
 XSERVER_IA32_MATROX_MGA = "xserver-xorg-module-xaa \
            xf86-video-mga \
            "
-
-- 
1.7.3.4

[meta-intel patch 2/3] xserver-psb: fix packaging issues

[nitin.a.kamble]

From: Nitin A Kamble <nitin.a.kamble@intel.com>

Because of the xserver recipe upgrade in the oecore layer, the
xserver packaging defined in the .inc file is changed. And this
change breaks the packaging of this older xserver recipe.
  This commit fixes the issue by using the meta-intel
specific version of the xserver-xorg.inc file.

This fixes bug:
[Yocto #3501]

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>
---
 .../xorg-xserver/xserver-psb-1.7.99.2.inc          |    2 +-
 .../xorg-xserver/xserver-psb_1.7.99.2.bb           |    2 +-
 2 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb-1.7.99.2.inc b/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb-1.7.99.2.inc
index 1fe962b..3004316 100644
--- a/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb-1.7.99.2.inc
+++ b/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb-1.7.99.2.inc
@@ -1,4 +1,4 @@
-PR = "r6"
+PR = "r7"
 
 PROTO_DEPS += "xf86driproto dri2proto"
 
diff --git a/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb_1.7.99.2.bb b/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb_1.7.99.2.bb
index 6b946d6..4cb5cd2 100644
--- a/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb_1.7.99.2.bb
+++ b/meta-emenlow/recipes-graphics/xorg-xserver/xserver-psb_1.7.99.2.bb
@@ -1,4 +1,4 @@
-require recipes-graphics/xorg-xserver/xserver-xorg.inc
+require common/recipes-graphics/xorg-xserver/xserver-xorg.inc
 require xserver-psb-${PV}.inc
 
 SRC_URI[md5sum] = "cafc4e2d4ef6cf6e47f3e7dffeb3346a"
-- 
1.7.3.4

[meta-intel patch 3/3] xserver-xorg-video-psb: fix packaging issues

[nitin.a.kamble]

From: Nitin A Kamble <nitin.a.kamble@intel.com>

This commit takes care of these packaging warnings.

WARNING: QA Issue: xserver-xorg-video-psb: Files/directories were installed but not shipped
  /usr/lib/xorg/modules/drivers/psb_drv.la
  /usr/lib/xorg/modules/drivers/libmm.la
  /usr/lib/xorg/modules/drivers/.debug
  /usr/lib/xorg/modules/drivers/.debug/psb_drv.so
  /usr/lib/xorg/modules/drivers/.debug/libmm.so

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>
---
 .../xserver-xorg-video-psb_0.32.1.bb               |    8 +++++++-
 1 files changed, 7 insertions(+), 1 deletions(-)

diff --git a/meta-emenlow/recipes-graphics/xserver-xorg-video-psb/xserver-xorg-video-psb_0.32.1.bb b/meta-emenlow/recipes-graphics/xserver-xorg-video-psb/xserver-xorg-video-psb_0.32.1.bb
index 7972fcd..afbf31b 100644
--- a/meta-emenlow/recipes-graphics/xserver-xorg-video-psb/xserver-xorg-video-psb_0.32.1.bb
+++ b/meta-emenlow/recipes-graphics/xserver-xorg-video-psb/xserver-xorg-video-psb_0.32.1.bb
@@ -1,7 +1,7 @@
 DESCRIPTION = "2D graphics driver for Poulsbo"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://MIT_License.txt;md5=732825ecdcf420261531d935fcd914a7"
-PR = "r3"
+PR = "r4"
 
 inherit autotools
 
@@ -37,3 +37,9 @@ DEPENDS += "virtual/libgl virtual/xserver"
 RDEPENDS_${PN} = "xserver-psb-module-exa"
 
 COMPATIBLE_MACHINE = "emenlow"
+
+do_install_append() {
+	find ${D}${libdir}/xorg/modules -regex ".*\.la$" | xargs rm -f --
+}
+
+FILES_${PN}-dbg += " ${libdir}/xorg/modules/drivers/.debug"
-- 
1.7.3.4

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Tom Zanussi]

On Wed, 2012-11-28 at 10:21 -0800, nitin.a.kamble@intel.com wrote:
> From: Nitin A Kamble <nitin.a.kamble@intel.com>
> 
> This commits are for meta-intel layer. And Ross'es patch tries to achieve the same 
> from the oecore layer.
> 

Hi Nitin,

So does this conflict with Ross's patch, which seems simpler...

Tom

> Thanks,
> Nitin
> 
> 
> The following changes since commit 154156a4db56f7b33fb1765cf6b87e683d027af9:
> 
>   emgd-driver-bin: add further needed soft links (2012-11-26 18:02:11 -0600)
> 
> are available in the git repository at:
>   git://git.yoctoproject.org/meta-intel-contrib nitin/misc
>   http://git.yoctoproject.org/cgit.cgi/meta-intel-contrib/log/?h=nitin/misc
> 
> Nitin A Kamble (3):
>   xserver-xorg-1.9.3: fix packaging issues
>   xserver-psb: fix packaging issues
>   xserver-xorg-video-psb: fix packaging issues
> 
>  .../xorg-xserver/xserver-xorg-1.9.3.inc            |    2 +-
>  .../recipes-graphics/xorg-xserver/xserver-xorg.inc |  160 ++++++++++++++++++++
>  .../xorg-xserver/xserver-xorg_1.9.3.bb             |    2 +-
>  conf/machine/include/meta-intel.inc                |   10 +-
>  .../xorg-xserver/xserver-psb-1.7.99.2.inc          |    2 +-
>  .../xorg-xserver/xserver-psb_1.7.99.2.bb           |    2 +-
>  .../xserver-xorg-video-psb_0.32.1.bb               |    8 +-
>  7 files changed, 180 insertions(+), 6 deletions(-)
>  create mode 100644 common/recipes-graphics/xorg-xserver/xserver-xorg.inc
> 

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Burton, Ross]

On 28 November 2012 20:07, Tom Zanussi <tom.zanussi@intel.com> wrote:
> So does this conflict with Ross's patch, which seems simpler...

I do prefer my patch as the same breakage will occur for anyone else
using oe-core master but also building their own older X server.
Whilst the delta is so minimal, I don't see the problem in supporting
both in oe-core.

Ross

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Tom Zanussi]

On Thu, 2012-11-29 at 11:27 +0000, Burton, Ross wrote:
> On 28 November 2012 20:07, Tom Zanussi <tom.zanussi@intel.com> wrote:
> > So does this conflict with Ross's patch, which seems simpler...
> 
> I do prefer my patch as the same breakage will occur for anyone else
> using oe-core master but also building their own older X server.
> Whilst the delta is so minimal, I don't see the problem in supporting
> both in oe-core.
> 

I'll second that...

Tom

> Ross

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Kamble, Nitin A]

> -----Original Message-----
> From: Zanussi, Tom
> Sent: Thursday, November 29, 2012 6:22 AM
> To: Burton, Ross
> Cc: Kamble, Nitin A; meta-intel@yoctoproject.org; Openembedded-
> core@lists.openembedded.org; Hart, Darren
> Subject: Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-
> intel layer
> 
> On Thu, 2012-11-29 at 11:27 +0000, Burton, Ross wrote:
> > On 28 November 2012 20:07, Tom Zanussi <tom.zanussi@intel.com> wrote:
> > > So does this conflict with Ross's patch, which seems simpler...
> >
> > I do prefer my patch as the same breakage will occur for anyone else
> > using oe-core master but also building their own older X server.
> > Whilst the delta is so minimal, I don't see the problem in supporting
> > both in oe-core.
> >
> 
> I'll second that...
> 
> Tom
> 
> > Ross
> 

I am fine with either approach for fixing the breakages. I will take Ross's patch and see if it fixes the issue I saw.

Nitin

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Kamble, Nitin A]

Ross,
  I tried applying your patch from here with git am, and it is failing. http://patches.openembedded.org/patch/39801/
Can you send me link to your contrib branch for the patch?

Thanks,
Nitin


> -----Original Message-----
> From: Kamble, Nitin A
> Sent: Thursday, November 29, 2012 8:50 AM
> To: Zanussi, Tom; Burton, Ross
> Cc: meta-intel@yoctoproject.org; Openembedded-
> core@lists.openembedded.org; Hart, Darren
> Subject: RE: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-
> intel layer
> 
> > -----Original Message-----
> > From: Zanussi, Tom
> > Sent: Thursday, November 29, 2012 6:22 AM
> > To: Burton, Ross
> > Cc: Kamble, Nitin A; meta-intel@yoctoproject.org; Openembedded-
> > core@lists.openembedded.org; Hart, Darren
> > Subject: Re: [meta-intel patch 0/3] Fixes for rescent X breakages in
> > meta- intel layer
> >
> > On Thu, 2012-11-29 at 11:27 +0000, Burton, Ross wrote:
> > > On 28 November 2012 20:07, Tom Zanussi <tom.zanussi@intel.com>
> wrote:
> > > > So does this conflict with Ross's patch, which seems simpler...
> > >
> > > I do prefer my patch as the same breakage will occur for anyone else
> > > using oe-core master but also building their own older X server.
> > > Whilst the delta is so minimal, I don't see the problem in
> > > supporting both in oe-core.
> > >
> >
> > I'll second that...
> >
> > Tom
> >
> > > Ross
> >
> 
> I am fine with either approach for fixing the breakages. I will take Ross's
> patch and see if it fixes the issue I saw.
> 
> Nitin
> 

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Kamble, Nitin A]

I finally got the Ross's patch working in my env. I need to add one more patch in meta-intel to get it fully working. 

So I Ack for Ross's patch in oecore, and I will send a small patch for meta-intel.

Thanks,
Nitin



> -----Original Message-----
> From: Kamble, Nitin A
> Sent: Friday, November 30, 2012 4:09 PM
> To: Zanussi, Tom; Burton, Ross
> Cc: 'meta-intel@yoctoproject.org'; 'Openembedded-
> core@lists.openembedded.org'; Hart, Darren
> Subject: RE: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-
> intel layer
> 
> Ross,
>   I tried applying your patch from here with git am, and it is failing.
> http://patches.openembedded.org/patch/39801/
> Can you send me link to your contrib branch for the patch?
> 
> Thanks,
> Nitin
> 
> 
> > -----Original Message-----
> > From: Kamble, Nitin A
> > Sent: Thursday, November 29, 2012 8:50 AM
> > To: Zanussi, Tom; Burton, Ross
> > Cc: meta-intel@yoctoproject.org; Openembedded-
> > core@lists.openembedded.org; Hart, Darren
> > Subject: RE: [meta-intel patch 0/3] Fixes for rescent X breakages in
> > meta- intel layer
> >
> > > -----Original Message-----
> > > From: Zanussi, Tom
> > > Sent: Thursday, November 29, 2012 6:22 AM
> > > To: Burton, Ross
> > > Cc: Kamble, Nitin A; meta-intel@yoctoproject.org; Openembedded-
> > > core@lists.openembedded.org; Hart, Darren
> > > Subject: Re: [meta-intel patch 0/3] Fixes for rescent X breakages in
> > > meta- intel layer
> > >
> > > On Thu, 2012-11-29 at 11:27 +0000, Burton, Ross wrote:
> > > > On 28 November 2012 20:07, Tom Zanussi <tom.zanussi@intel.com>
> > wrote:
> > > > > So does this conflict with Ross's patch, which seems simpler...
> > > >
> > > > I do prefer my patch as the same breakage will occur for anyone
> > > > else using oe-core master but also building their own older X server.
> > > > Whilst the delta is so minimal, I don't see the problem in
> > > > supporting both in oe-core.
> > > >
> > >
> > > I'll second that...
> > >
> > > Tom
> > >
> > > > Ross
> > >
> >
> > I am fine with either approach for fixing the breakages. I will take
> > Ross's patch and see if it fixes the issue I saw.
> >
> > Nitin
> >

Re: [meta-intel patch 0/3] Fixes for rescent X breakages in meta-intel layer

[Tom Zanussi]

On Thu, 2012-11-29 at 08:21 -0600, Tom Zanussi wrote:
> On Thu, 2012-11-29 at 11:27 +0000, Burton, Ross wrote:
> > On 28 November 2012 20:07, Tom Zanussi <tom.zanussi@intel.com> wrote:
> > > So does this conflict with Ross's patch, which seems simpler...
> > 
> > I do prefer my patch as the same breakage will occur for anyone else
> > using oe-core master but also building their own older X server.
> > Whilst the delta is so minimal, I don't see the problem in supporting
> > both in oe-core.
> > 
> 
> I'll second that...
> 

Did anyone test this?  I'm getting:

1558733.206] (WW) Warning, couldn't open module dri
[1558733.206] (II) UnloadModule: "dri"
[1558733.206] (EE) Failed to load module "dri" (module does not exist,
0)
[1558733.206] (II) LoadModule: "dri2"
[1558733.207] (WW) Warning, couldn't open module dri2
[1558733.207] (II) UnloadModule: "dri2"


> Tom
> 
> > Ross
>