[PATCH 00/12] Further check-layer fixes

[PATCH 00/12] Further check-layer fixes

[Paul Barker]

This series follows on from the two patches I sent earlier this week
[1], and Richard's patch to fix [2]. With all these applied, most of the
check-layer failures in openembedded-core are resolved, with two
exceptions:

  - mesa:do_recipe_qa signature changes based on MACHINE due to use of
    VULKAN_DRIVES in PACKAGECONFIG. However, adding VULKAN_DRIVERS to
    PACKAGECONFIG[vardeps] doesn't fix the issue.

  - lttng-ust:do_recipe_qa signature changes based on MACHINE due to use
    of PYTHON_OPTION (-> PYTHON_SITEPACKAGES_DIR -> libdir) in
    PACKAGECONFIG. However, adding PYTHON_OPTION or
    PYTHON_SITEPACKAGES_DIR to PACKAGECONFIG[vardeps] doesn't fix the
    issue.

There may be a couple of other things that need investigating to make
everything pass, but I wanted to get validation on this initial set of
fixes now. In particular, is setting PACKAGECONFIG[vardeps] the right
thing to do?

[1]: https://lore.kernel.org/openembedded-core/20260316-fix-checklayer-v1-0-f3bcaa60e93c@pbarker.dev/
[2]: https://lore.kernel.org/openembedded-core/20260317121307.935437-1-richard.purdie@linuxfoundation.org/

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
Paul Barker (12):
      checklayer: Fix regex in get_signatures
      curl: Drop arch dependent search paths
      ghostscript: Drop arch dependent search paths
      libssh2: Drop arch dependent search paths
      flac: Use arch independent search path
      gettext: Use arch independent search paths
      gnutls: Use arch independent search paths
      initscripts: Make SRC_URI arch independent
      linux-yocto: Avoid arch dependent vardeps for SRC_URI
      libsdl2: Explicitly set PACKAGECONFIG vardeps
      graphene: Explicitly set PACKAGECONFIG vardeps
      gstreamer1.0-plugins-good: Explicitly set PACKAGECONFIG vardeps

 meta/recipes-core/gettext/gettext_1.0.bb                             | 4 ++--
 meta/recipes-core/initscripts/initscripts_1.0.bb                     | 4 +---
 meta/recipes-extended/ghostscript/ghostscript_10.06.0.bb             | 3 +--
 meta/recipes-graphics/graphene/graphene_1.10.8.bb                    | 3 +++
 meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb                     | 3 +++
 meta/recipes-kernel/linux/linux-yocto.inc                            | 5 +++++
 meta/recipes-multimedia/flac/flac_1.5.0.bb                           | 2 +-
 .../recipes-multimedia/gstreamer/gstreamer1.0-plugins-good_1.26.9.bb | 3 +++
 meta/recipes-support/curl/curl_8.19.0.bb                             | 2 +-
 meta/recipes-support/gnutls/gnutls_3.8.12.bb                         | 4 ++--
 meta/recipes-support/libssh2/libssh2_1.11.1.bb                       | 3 +--
 scripts/lib/checklayer/__init__.py                                   | 2 +-
 12 files changed, 24 insertions(+), 14 deletions(-)
---
base-commit: 531f87111d83430615f2e20dd41a3dd5fc25c7ab
change-id: 20260318-fix-checklayer-2-af057a82ca74

Best regards,
-- 
Paul Barker

[PATCH 01/12] checklayer: Fix regex in get_signatures

[Paul Barker]

After commit 11373def3171 ("sstatesig/populate_sdk_ext: Improve unihash
cache handling") in openembedded-core, the locked-sigs.inc file may
contain unihash map entries as well as a list of locked sigs. The
unihash map entries consist of four fields separated by `:` - pn, task,
task hash and unihash. The current regex in get_signatures cannot parse
these correctly, it grabs the first 3 elements into <task> when there
should only be two elements, leading to an error:

    Traceback (most recent call last):
      File "/srv/pokybuild/yocto-worker/check-layer/build/layers/openembedded-core/scripts/yocto-check-layer", line 252, in <module>
        ret =  main()
      File "/srv/pokybuild/yocto-worker/check-layer/build/layers/openembedded-core/scripts/yocto-check-layer", line 215, in main
        td['sigs'], td['tunetasks'] = get_signatures(td['builddir'])
                                      ~~~~~~~~~~~~~~^^^^^^^^^^^^^^^^
      File "/srv/pokybuild/yocto-worker/check-layer/build/layers/openembedded-core/scripts/lib/checklayer/__init__.py", line 340, in get_signatures
        (recipe, task) = s.group('task').split(':')
        ^^^^^^^^^^^^^^
    ValueError: too many values to unpack (expected 2)

Modify the regex so that it doesn't accidentally pick up the third field
of the unihash map entries.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 scripts/lib/checklayer/__init__.py | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/scripts/lib/checklayer/__init__.py b/scripts/lib/checklayer/__init__.py
index b70cef1b1441..15459b6e0486 100644
--- a/scripts/lib/checklayer/__init__.py
+++ b/scripts/lib/checklayer/__init__.py
@@ -324,7 +324,7 @@ def get_signatures(builddir, failsafe=False, machine=None, extravars=None):
         else:
             raise
 
-    sig_regex = re.compile(r"^(?P<task>.*:.*):(?P<hash>.*) .$")
+    sig_regex = re.compile(r"^(?P<task>[^:]*:[^:]*):(?P<hash>.*) .$")
     tune_regex = re.compile(r"(^|\s)SIGGEN_LOCKEDSIGS_t-(?P<tune>\S*)\s*=\s*")
     current_tune = None
     with open(sigs_file, 'r') as f:

-- 
2.43.0

[PATCH 02/12] curl: Drop arch dependent search paths

[Paul Barker]

Since the creation of the curl recipe in this repo in 2010, the search
path has been specified relative to STAGING_LIBDIR. This causes the a
dependency from the task hash of do_recipe_qa on baselib, which may be
'lib' or 'lib64' depending on the target architecture. This dependency
trips up yocto-check-layer.

Somewhere between the depths of history and today, the need for this
search path has gone away. Simply using '--with-zlib' now works.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-support/curl/curl_8.19.0.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-support/curl/curl_8.19.0.bb b/meta/recipes-support/curl/curl_8.19.0.bb
index ee9c90846d19..b9251336b8b3 100644
--- a/meta/recipes-support/curl/curl_8.19.0.bb
+++ b/meta/recipes-support/curl/curl_8.19.0.bb
@@ -73,7 +73,7 @@ PACKAGECONFIG[tftp] = "--enable-tftp,--disable-tftp,"
 PACKAGECONFIG[threaded-resolver] = "--enable-threaded-resolver,--disable-threaded-resolver,,,,ares"
 PACKAGECONFIG[verbose] = "--enable-verbose,--disable-verbose"
 PACKAGECONFIG[websockets] = "--enable-websockets,--disable-websockets"
-PACKAGECONFIG[zlib] = "--with-zlib=${STAGING_LIBDIR}/../,--without-zlib,zlib"
+PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib"
 PACKAGECONFIG[zstd] = "--with-zstd,--without-zstd,zstd"
 
 # Use host certificates for non-target builds. As libcurl doesn't honor any of the env vars (like

-- 
2.43.0

[PATCH 03/12] ghostscript: Drop arch dependent search paths

[Paul Barker]

The value of STAGING_LIBDIR depends on baselib, which may be "lib" or
"lib64" depending on the target architecture. To avoid making
PACKAGECONFIG unnecessarily arch-dependent, we can use drop the search
prefix for x11 libraries as the configure script is capable of finding
them without this information.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-extended/ghostscript/ghostscript_10.06.0.bb | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/meta/recipes-extended/ghostscript/ghostscript_10.06.0.bb b/meta/recipes-extended/ghostscript/ghostscript_10.06.0.bb
index 4cea89843283..b0951d79f5f4 100644
--- a/meta/recipes-extended/ghostscript/ghostscript_10.06.0.bb
+++ b/meta/recipes-extended/ghostscript/ghostscript_10.06.0.bb
@@ -33,8 +33,7 @@ PACKAGECONFIG ??= ""
 PACKAGECONFIG[gtk] = "--enable-gtk,--disable-gtk,gtk+3"
 PACKAGECONFIG[libidn] = "--with-libidn,--without-libidn,libidn"
 PACKAGECONFIG[libpaper] = "--with-libpaper,--without-libpaper,libpaper"
-PACKAGECONFIG[x11] = "--with-x --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR}, \
-                      --without-x, virtual/libx11 libxext libxt"
+PACKAGECONFIG[x11] = "--with-x, --without-x, virtual/libx11 libxext libxt"
 
 EXTRA_OECONF = "--with-jbig2dec \
                 --with-fontpath=${datadir}/fonts \

-- 
2.43.0

[PATCH 04/12] libssh2: Drop arch dependent search paths

[Paul Barker]

The value of STAGING_LIBDIR depends on baselib, which may be "lib" or
"lib64" depending on the target architecture. To avoid making
PACKAGECONFIG unnecessarily arch-dependent, we can use drop the search
prefix for libz and openssl as the configure script is capable of
finding them without this information.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-support/libssh2/libssh2_1.11.1.bb | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/meta/recipes-support/libssh2/libssh2_1.11.1.bb b/meta/recipes-support/libssh2/libssh2_1.11.1.bb
index 11d744868700..271bd14bed7f 100644
--- a/meta/recipes-support/libssh2/libssh2_1.11.1.bb
+++ b/meta/recipes-support/libssh2/libssh2_1.11.1.bb
@@ -18,14 +18,13 @@ inherit autotools pkgconfig ptest
 
 EXTRA_OECONF += "\
                  --with-libz \
-                 --with-libz-prefix=${STAGING_LIBDIR} \
                  --disable-rpath \
                 "
 DISABLE_STATIC = ""
 
 # only one of openssl and gcrypt could be set
 PACKAGECONFIG ??= "openssl"
-PACKAGECONFIG[openssl] = "--with-crypto=openssl --with-libssl-prefix=${STAGING_LIBDIR}, , openssl"
+PACKAGECONFIG[openssl] = "--with-crypto=openssl, , openssl"
 PACKAGECONFIG[gcrypt] = "--with-crypto=libgcrypt --with-libgcrypt-prefix=${STAGING_EXECPREFIXDIR}, , libgcrypt"
 
 BBCLASSEXTEND = "native nativesdk"

-- 
2.43.0

[PATCH 05/12] flac: Use arch independent search path

[Paul Barker]

The value of STAGING_LIBDIR depends on baselib, which may be "lib" or
"lib64" depending on the target architecture. To avoid making
PACKAGECONFIG unnecessarily arch-dependent, we can use STAGING_DIR_HOST
as the search prefix for libogg instead.

The search prefix is necessary here, removing it completely results in
compilation errors.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-multimedia/flac/flac_1.5.0.bb | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/meta/recipes-multimedia/flac/flac_1.5.0.bb b/meta/recipes-multimedia/flac/flac_1.5.0.bb
index e227133ad794..2f43b4e84b24 100644
--- a/meta/recipes-multimedia/flac/flac_1.5.0.bb
+++ b/meta/recipes-multimedia/flac/flac_1.5.0.bb
@@ -34,7 +34,7 @@ PACKAGECONFIG ??= " \
     ogg \
 "
 PACKAGECONFIG[avx] = "--enable-avx,--disable-avx"
-PACKAGECONFIG[ogg] = "--enable-ogg --with-ogg-libraries=${STAGING_LIBDIR} --with-ogg-includes=${STAGING_INCDIR},--disable-ogg,libogg"
+PACKAGECONFIG[ogg] = "--enable-ogg --with-ogg=${STAGING_DIR_HOST},--disable-ogg,libogg"
 
 PACKAGES += "libflac libflac++"
 FILES:${PN} = "${bindir}/*"

-- 
2.43.0

[PATCH 06/12] gettext: Use arch independent search paths

[Paul Barker]

The value of STAGING_LIBDIR depends on baselib, which may be "lib" or
"lib64" depending on the target architecture. To avoid making
PACKAGECONFIG unnecessarily arch-dependent, we can use STAGING_DIR_HOST
as the search prefix for libunistring & ncurses instead.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-core/gettext/gettext_1.0.bb | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-core/gettext/gettext_1.0.bb b/meta/recipes-core/gettext/gettext_1.0.bb
index 37e46869a7b6..e20ad8807def 100644
--- a/meta/recipes-core/gettext/gettext_1.0.bb
+++ b/meta/recipes-core/gettext/gettext_1.0.bb
@@ -63,8 +63,8 @@ PACKAGECONFIG[glib] = "--without-included-glib,--with-included-glib,glib-2.0"
 PACKAGECONFIG[libxml] = "--without-included-libxml,--with-included-libxml,libxml2"
 # Need paths here to avoid host contamination but this can cause RPATH warnings
 # or problems if $libdir isn't $prefix/lib.
-PACKAGECONFIG[libunistring] = "--with-libunistring-prefix=${STAGING_LIBDIR}/..,--with-included-libunistring,libunistring"
-PACKAGECONFIG[msgcat-curses] = "--with-libncurses-prefix=${STAGING_LIBDIR}/..,--disable-curses,ncurses,"
+PACKAGECONFIG[libunistring] = "--with-libunistring-prefix=${STAGING_DIR_HOST},--with-included-libunistring,libunistring"
+PACKAGECONFIG[msgcat-curses] = "--with-libncurses-prefix=${STAGING_DIR_HOST},--disable-curses,ncurses,"
 PACKAGECONFIG[selinux] = "--with-selinux,--without-selinux --disable-acl,attr libselinux"
 
 do_install:append:libc-musl () {

-- 
2.43.0

[PATCH 07/12] gnutls: Use arch independent search paths

[Paul Barker]

The value of STAGING_LIBDIR depends on baselib, which may be "lib" or
"lib64" depending on the target architecture. To avoid making
PACKAGECONFIG unnecessarily arch-dependent, we can use STAGING_DIR_HOST
as the search prefix for libseccomp & libdl instead.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-support/gnutls/gnutls_3.8.12.bb | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-support/gnutls/gnutls_3.8.12.bb b/meta/recipes-support/gnutls/gnutls_3.8.12.bb
index c601d34069e4..92156c277c94 100644
--- a/meta/recipes-support/gnutls/gnutls_3.8.12.bb
+++ b/meta/recipes-support/gnutls/gnutls_3.8.12.bb
@@ -34,12 +34,12 @@ PACKAGECONFIG ??= "libidn libtasn1 ${@bb.utils.filter('DISTRO_FEATURES', 'seccom
 
 # You must also have CONFIG_SECCOMP enabled in the kernel for
 # seccomp to work.
-PACKAGECONFIG[seccomp] = "--with-libseccomp-prefix=${STAGING_EXECPREFIXDIR},ac_cv_libseccomp=no,libseccomp"
+PACKAGECONFIG[seccomp] = "--with-libseccomp-prefix=${STAGING_DIR_HOST},ac_cv_libseccomp=no,libseccomp"
 PACKAGECONFIG[libidn] = "--with-idn,--without-idn,libidn2"
 PACKAGECONFIG[libtasn1] = "--without-included-libtasn1,--with-included-libtasn1,libtasn1"
 PACKAGECONFIG[p11-kit] = "--with-p11-kit,--without-p11-kit,p11-kit"
 PACKAGECONFIG[tpm] = "--with-tpm,--without-tpm,trousers"
-PACKAGECONFIG[fips] = "--enable-fips140-mode --with-libdl-prefix=${STAGING_BASELIBDIR}"
+PACKAGECONFIG[fips] = "--enable-fips140-mode --with-libdl-prefix=${STAGING_DIR_HOST}"
 PACKAGECONFIG[dane] = "--enable-libdane,--disable-libdane,unbound"
 # Certificate compression
 PACKAGECONFIG[brotli] = "--with-brotli,--without-brotli,brotli"

-- 
2.43.0

[PATCH 08/12] initscripts: Make SRC_URI arch independent

[Paul Barker]

Avoid making SRC_URI unnecessarily dependent on the target architecture.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-core/initscripts/initscripts_1.0.bb | 4 +---
 1 file changed, 1 insertion(+), 3 deletions(-)

diff --git a/meta/recipes-core/initscripts/initscripts_1.0.bb b/meta/recipes-core/initscripts/initscripts_1.0.bb
index c984257c5c8f..23411b6a7149 100644
--- a/meta/recipes-core/initscripts/initscripts_1.0.bb
+++ b/meta/recipes-core/initscripts/initscripts_1.0.bb
@@ -32,14 +32,12 @@ SRC_URI = "file://functions \
            file://save-rtc.sh \
            file://dmesg.sh \
            file://logrotate-dmesg.conf \
+           file://alignment.sh \
            ${@bb.utils.contains('DISTRO_FEATURES','selinux','file://sushell','',d)} \
 "
 
 S = "${UNPACKDIR}"
 
-SRC_URI:append:arm = " file://alignment.sh"
-SRC_URI:append:armeb = " file://alignment.sh"
-
 KERNEL_VERSION = ""
 
 DEPENDS:append = " update-rc.d-native"

-- 
2.43.0

Re: [OE-core] [PATCH 08/12] initscripts: Make SRC_URI arch independent

[Richard Purdie]

On Wed, 2026-03-18 at 17:14 +0000, Paul Barker via lists.openembedded.org wrote:
> Avoid making SRC_URI unnecessarily dependent on the target architecture.
> 
> Signed-off-by: Paul Barker <paul@pbarker.dev>
> ---
>  meta/recipes-core/initscripts/initscripts_1.0.bb | 4 +---
>  1 file changed, 1 insertion(+), 3 deletions(-)
> 
> diff --git a/meta/recipes-core/initscripts/initscripts_1.0.bb b/meta/recipes-core/initscripts/initscripts_1.0.bb
> index c984257c5c8f..23411b6a7149 100644
> --- a/meta/recipes-core/initscripts/initscripts_1.0.bb
> +++ b/meta/recipes-core/initscripts/initscripts_1.0.bb
> @@ -32,14 +32,12 @@ SRC_URI = "file://functions \
>             file://save-rtc.sh \
>             file://dmesg.sh \
>             file://logrotate-dmesg.conf \
> +           file://alignment.sh \
>             ${@bb.utils.contains('DISTRO_FEATURES','selinux','file://sushell','',d)} \
>  "
>  
>  S = "${UNPACKDIR}"
>  
> -SRC_URI:append:arm = " file://alignment.sh"
> -SRC_URI:append:armeb = " file://alignment.sh"
> -
> 


alignment.sh is pointless outside of arm. The commit message needs to
mention that the installation of it is still conditional on the arm
arch.

Cheers,

Richard

[PATCH 09/12] linux-yocto: Avoid arch dependent vardeps for SRC_URI

[Paul Barker]

yocto-check-layer will fail if SRC_URI is dependent on the target
architecture. Usually we would try to remove the dependency, but for the
linux-yocto recipe it's necessary in order to select the appropriate
branch from the source repository.

As none of the checks performed by yocto-check-layer actually depend on
the selected branch, we can discard this depedency by specifying a
generic vardepvalue for the branch name.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-kernel/linux/linux-yocto.inc | 5 +++++
 1 file changed, 5 insertions(+)

diff --git a/meta/recipes-kernel/linux/linux-yocto.inc b/meta/recipes-kernel/linux/linux-yocto.inc
index f47873348a9a..18f910f34e56 100644
--- a/meta/recipes-kernel/linux/linux-yocto.inc
+++ b/meta/recipes-kernel/linux/linux-yocto.inc
@@ -93,3 +93,8 @@ do_devshell:prepend() {
     d.setVar("HOSTPKG_CONFIG", "pkg-config-native")
     d.appendVar("OE_TERMINAL_EXPORTS", " HOSTPKG_CONFIG")
 }
+
+# Avoid potentially architecture dependent value when evaluating vardeps of
+# SRC_URI. This does mean do_recipe_qa may not re-run when KBRANCH changes, but
+# that should not invalidate the QA test.
+KBRANCH[vardepvalue] = "master"

-- 
2.43.0

[PATCH 10/12] libsdl2: Explicitly set PACKAGECONFIG vardeps

[Paul Barker]

The variable dependencies are discarded for PACKAGECONFIG, which may
cause tasks which use the value of PACKAGECONFIG to be considered
arch-independent, even when the value is actually different depending on
the target architecture.

In this case, we use the value of TUNE_FEATURES in PACKAGECONFIG, which
is obviously arch-dependent so we should explicitly list this
dependency.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb b/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb
index 834cf096b977..f7c292b6adb0 100644
--- a/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb
+++ b/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb
@@ -80,6 +80,9 @@ PACKAGECONFIG[vulkan]    = "-DSDL_VULKAN=ON,-DSDL_VULKAN=OFF"
 PACKAGECONFIG[wayland]    = "-DSDL_WAYLAND=ON,-DSDL_WAYLAND=OFF,wayland-native wayland wayland-protocols libxkbcommon"
 PACKAGECONFIG[x11]        = "-DSDL_X11=ON,-DSDL_X11=OFF,virtual/libx11 libxext libxrandr libxrender"
 
+# PACKAGECONFIG dependencies are not automatically carried forwards
+PACKAGECONFIG[vardeps] += "TUNE_FEATURES"
+
 CFLAGS:append:class-native = " -DNO_SHARED_MEMORY"
 
 FILES:${PN} += "${datadir}/licenses/SDL2/LICENSE.txt"

-- 
2.43.0

Re: [OE-core] [PATCH 10/12] libsdl2: Explicitly set PACKAGECONFIG vardeps

[Richard Purdie]

On Wed, 2026-03-18 at 17:14 +0000, Paul Barker via lists.openembedded.org wrote:
> The variable dependencies are discarded for PACKAGECONFIG, which may
> cause tasks which use the value of PACKAGECONFIG to be considered
> arch-independent, even when the value is actually different depending on
> the target architecture.
> 
> In this case, we use the value of TUNE_FEATURES in PACKAGECONFIG, which
> is obviously arch-dependent so we should explicitly list this
> dependency.
> 
> Signed-off-by: Paul Barker <paul@pbarker.dev>
> ---
>  meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb | 3 +++
>  1 file changed, 3 insertions(+)
> 
> diff --git a/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb b/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb
> index 834cf096b977..f7c292b6adb0 100644
> --- a/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb
> +++ b/meta/recipes-graphics/libsdl2/libsdl2_2.32.10.bb
> @@ -80,6 +80,9 @@ PACKAGECONFIG[vulkan]    = "-DSDL_VULKAN=ON,-DSDL_VULKAN=OFF"
>  PACKAGECONFIG[wayland]    = "-DSDL_WAYLAND=ON,-DSDL_WAYLAND=OFF,wayland-native wayland wayland-protocols libxkbcommon"
>  PACKAGECONFIG[x11]        = "-DSDL_X11=ON,-DSDL_X11=OFF,virtual/libx11 libxext libxrandr libxrender"
>  
> +# PACKAGECONFIG dependencies are not automatically carried forwards
> +PACKAGECONFIG[vardeps] += "TUNE_FEATURES"

I'm not understanding the issue here.

I added a vardepvalue for PACKAGECONFIG but the usage of TUNE_FEATURES
here shouldn't matter, the expanded value will differ and that should
be all we need for the taskhashes to work properly.

What issue are you trying to solve here?

Cheers,

Richard

[PATCH 11/12] graphene: Explicitly set PACKAGECONFIG vardeps

[Paul Barker]

The variable dependencies are discarded for PACKAGECONFIG, which may
cause tasks which use the value of PACKAGECONFIG to be considered
arch-independent, even when the value is actually different depending on
the target architecture.

In this case, we use the value of TUNE_FEATURES in PACKAGECONFIG, which
is obviously arch-dependent so we should explicitly list this
dependency.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-graphics/graphene/graphene_1.10.8.bb | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-graphics/graphene/graphene_1.10.8.bb b/meta/recipes-graphics/graphene/graphene_1.10.8.bb
index d14a6403ff43..5a051af1ca35 100644
--- a/meta/recipes-graphics/graphene/graphene_1.10.8.bb
+++ b/meta/recipes-graphics/graphene/graphene_1.10.8.bb
@@ -16,6 +16,9 @@ PACKAGECONFIG ?= "gobject-types ${@bb.utils.contains('TUNE_FEATURES', 'aarch64',
 PACKAGECONFIG[gobject-types] = "-Dgobject_types=true,-Dgobject_types=false,glib-2.0"
 PACKAGECONFIG[neon] = "-Darm_neon=true,-Darm_neon=false,"
 
+# PACKAGECONFIG dependencies are not automatically carried forwards
+PACKAGECONFIG[vardeps] += "TUNE_FEATURES"
+
 GIR_MESON_ENABLE_FLAG = 'enabled'
 GIR_MESON_DISABLE_FLAG = 'disabled'
 

-- 
2.43.0

[PATCH 12/12] gstreamer1.0-plugins-good: Explicitly set PACKAGECONFIG vardeps

[Paul Barker]

The variable dependencies are discarded for PACKAGECONFIG, which may
cause tasks which use the value of PACKAGECONFIG to be considered
arch-independent, even when the value is actually different depending on
the target architecture.

In this case, we use the value of TUNE_FEATURES in PACKAGECONFIG, which
is obviously arch-dependent so we should explicitly list this
dependency.

Signed-off-by: Paul Barker <paul@pbarker.dev>
---
 meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-good_1.26.9.bb | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-good_1.26.9.bb b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-good_1.26.9.bb
index e7ca26406d96..3959a5aec2df 100644
--- a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-good_1.26.9.bb
+++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-good_1.26.9.bb
@@ -27,6 +27,9 @@ PACKAGECONFIG ??= " \
     bz2 cairo flac gdk-pixbuf gudev jpeg lame libpng mpg123 speex taglib v4l2 \
 "
 
+# PACKAGECONFIG dependencies are not automatically carried forwards
+PACKAGECONFIG[vardeps] += "TUNE_FEATURES"
+
 X11DEPENDS = "virtual/libx11 libsm libxrender libxfixes libxdamage"
 X11ENABLEOPTS = "-Dximagesrc=enabled -Dximagesrc-xshm=enabled -Dximagesrc-xfixes=enabled -Dximagesrc-xdamage=enabled"
 X11DISABLEOPTS = "-Dximagesrc=disabled -Dximagesrc-xshm=disabled -Dximagesrc-xfixes=disabled -Dximagesrc-xdamage=disabled"

-- 
2.43.0