Poky Project Discussions
 help / color / mirror / Atom feed
* [PATCH 4/4] kernelshark: add ftrace gui viewer
  2011-01-03 17:46 [PATCH 0/4 V2] tracing: trace-cmd fixes and new kernelshark recipe Darren Hart
@ 2010-12-29  1:10 ` Darren Hart
  2011-01-03 19:04   ` Richard Purdie
  2011-01-03 19:06   ` Darren Hart
  2010-12-29  1:17 ` [PATCH 1/4] trace-cmd: fix cross-compilation Darren Hart
                   ` (2 subsequent siblings)
  3 siblings, 2 replies; 10+ messages in thread
From: Darren Hart @ 2010-12-29  1:10 UTC (permalink / raw)
  To: poky, sgw

The trace-cmd source includes a graphical trace viewer, but we
don't want to make the trace-cmd recipe depend on gtk+. This
patch adds a second recipe in the meta/recipes-kernel/trace-cmd
directory which uses the trace-cmd SRCREV and RDEPENDS on trace-cmd
to ensure compatibility.

Signed-off-by: Darren Hart <dvhart@linux.intel.com>
CC: Tom Zanussi <tom.zanussi@intel.com>
---
 meta/recipes-kernel/trace-cmd/kernelshark_git.bb |   22 ++++++++++++++++++++++
 1 files changed, 22 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-kernel/trace-cmd/kernelshark_git.bb

diff --git a/meta/recipes-kernel/trace-cmd/kernelshark_git.bb b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
new file mode 100644
index 0000000..781f983
--- /dev/null
+++ b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
@@ -0,0 +1,22 @@
+DESCRIPTION = "Graphical trace viewer for Ftrace"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://kernelshark.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e"
+
+PR = r0
+PV = "1.0.4+git${SRCPV}"
+
+DEPENDS = "gtk+"
+RDEPENDS = "trace-cmd"
+
+inherit pkgconfig
+
+SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/rostedt/trace-cmd.git;protocol=git"
+SRCREV = "${SRCREV_pn-trace-cmd}"
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "'CC=${CC}' 'AR=${AR}' 'prefix=${prefix}' gui"
+
+do_install() {
+	oe_runmake CC="${CC}" AR="${AR}" prefix="${prefix}" DESTDIR="${D}" install_gui
+}
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 10+ messages in thread

* [PATCH 1/4] trace-cmd: fix cross-compilation
  2011-01-03 17:46 [PATCH 0/4 V2] tracing: trace-cmd fixes and new kernelshark recipe Darren Hart
  2010-12-29  1:10 ` [PATCH 4/4] kernelshark: add ftrace gui viewer Darren Hart
@ 2010-12-29  1:17 ` Darren Hart
  2010-12-29 18:10 ` [PATCH 3/4] glib-2.0: fix g_once_init_enter compile failure Darren Hart
  2011-01-03 17:39 ` [PATCH 2/4] trace-cmd: license file updates Darren Hart
  3 siblings, 0 replies; 10+ messages in thread
From: Darren Hart @ 2010-12-29  1:17 UTC (permalink / raw)
  To: poky, sgw

The trace-cmd Makefile forces certain variables, such as CC and AR.
It was using the host gcc and loader, fix it to use the poky-built
cross-compiler and linker.

inherit pkgconfig to ensure we don't use the host pkg-config.

Remove unecessary variables from the oemake commands, such as ARCH
and LD which aren't used by the Makefile.

Signed-off-by: Darren Hart <dvhart@linux.intel.com>
CC: Tom Zanussi <tom.zanussi@intel.com>
---
 meta/recipes-kernel/trace-cmd/trace-cmd_git.bb |   12 +++++-------
 1 files changed, 5 insertions(+), 7 deletions(-)

diff --git a/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb b/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb
index e375afc..a7eca5f 100644
--- a/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb
+++ b/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb
@@ -2,18 +2,16 @@ DESCRIPTION = "User interface to Ftrace"
 LICENSE = "GPL"
 LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
 
-PR = r1
+PR = r2
 PV = "1.0.4+git${SRCPV}"
 
+inherit pkgconfig
+
 SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/rostedt/trace-cmd.git;protocol=git"
 S = "${WORKDIR}/git"
 
-
-do_compile() { 
-	oe_runmake ARCH="${ARCH}" CC="${CC}" LD="${LD}" prefix=${prefix}
-}
+EXTRA_OEMAKE = "'CC=${CC}' 'AR=${AR}' 'prefix=${prefix}'"
 
 do_install() {
-	oe_runmake ARCH="${ARCH}" CC="${CC}" LD="${LD}" \
-                   prefix=${prefix} DESTDIR=${D} install
+	oe_runmake CC="${CC}" AR="${AR}" prefix="${prefix}" DESTDIR="${D}" install
 }
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 10+ messages in thread

* [PATCH 3/4] glib-2.0: fix g_once_init_enter compile failure
  2011-01-03 17:46 [PATCH 0/4 V2] tracing: trace-cmd fixes and new kernelshark recipe Darren Hart
  2010-12-29  1:10 ` [PATCH 4/4] kernelshark: add ftrace gui viewer Darren Hart
  2010-12-29  1:17 ` [PATCH 1/4] trace-cmd: fix cross-compilation Darren Hart
@ 2010-12-29 18:10 ` Darren Hart
  2011-01-03 17:39 ` [PATCH 2/4] trace-cmd: license file updates Darren Hart
  3 siblings, 0 replies; 10+ messages in thread
From: Darren Hart @ 2010-12-29 18:10 UTC (permalink / raw)
  To: poky, sgw

Kernelshark trips over a compile bug in glib-2.0 addressed by Open Embedded
back in the 2.22 timeframe. It appears to still be present in 2.27.

http://www.mail-archive.com/openembedded-devel@lists.openembedded.org/msg00529.html

Signed-off-by: Darren Hart <dvhart@linux.intel.com>
CC: Tom Zanussi <tom.zanussi@intel.com>
---
 .../glib-2.0-2.27.3/g_once_init_enter.patch        |   13 +++++++++++++
 meta/recipes-core/glib-2.0/glib-2.0_2.27.3.bb      |    6 ++++--
 2 files changed, 17 insertions(+), 2 deletions(-)
 create mode 100644 meta/recipes-core/glib-2.0/glib-2.0-2.27.3/g_once_init_enter.patch

diff --git a/meta/recipes-core/glib-2.0/glib-2.0-2.27.3/g_once_init_enter.patch b/meta/recipes-core/glib-2.0/glib-2.0-2.27.3/g_once_init_enter.patch
new file mode 100644
index 0000000..1c4ce50
--- /dev/null
+++ b/meta/recipes-core/glib-2.0/glib-2.0-2.27.3/g_once_init_enter.patch
@@ -0,0 +1,13 @@
+Index: glib-2.27.3/glib/gthread.h
+===================================================================
+--- glib-2.27.3.orig/glib/gthread.h
++++ glib-2.27.3/glib/gthread.h
+@@ -344,7 +344,7 @@ void                    g_once_init_leav
+ G_INLINE_FUNC gboolean
+ g_once_init_enter (volatile gsize *value_location)
+ {
+-  if G_LIKELY ((gpointer) g_atomic_pointer_get (value_location) != NULL)
++  if G_LIKELY ((gpointer) g_atomic_pointer_get ((volatile gpointer *)value_location) != NULL)
+     return FALSE;
+   else
+     return g_once_init_enter_impl (value_location);
diff --git a/meta/recipes-core/glib-2.0/glib-2.0_2.27.3.bb b/meta/recipes-core/glib-2.0/glib-2.0_2.27.3.bb
index 30e208a..a9ff3ec 100644
--- a/meta/recipes-core/glib-2.0/glib-2.0_2.27.3.bb
+++ b/meta/recipes-core/glib-2.0/glib-2.0_2.27.3.bb
@@ -1,10 +1,12 @@
 require glib.inc
 
-PR = "r0"
+PR = "r1"
 
 SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/glib/2.27/glib-${PV}.tar.bz2 \
            file://configure-libtool.patch \
-           file://60_wait-longer-for-threads-to-die.patch"
+           file://60_wait-longer-for-threads-to-die.patch \
+           file://g_once_init_enter.patch \
+          "
 
 SRC_URI[md5sum] = "d3e976ff92b55b6064a0eb3110f36158"
 SRC_URI[sha256sum] = "c44177b635e88639361eb1daf7aaa33315a00aaf46db5accf2f11920c7ff1919"
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 10+ messages in thread

* [PATCH 2/4] trace-cmd: license file updates
  2011-01-03 17:46 [PATCH 0/4 V2] tracing: trace-cmd fixes and new kernelshark recipe Darren Hart
                   ` (2 preceding siblings ...)
  2010-12-29 18:10 ` [PATCH 3/4] glib-2.0: fix g_once_init_enter compile failure Darren Hart
@ 2011-01-03 17:39 ` Darren Hart
  3 siblings, 0 replies; 10+ messages in thread
From: Darren Hart @ 2011-01-03 17:39 UTC (permalink / raw)
  To: poky, sgw

Signed-off-by: Darren Hart <dvhart@linux.intel.com>
---
 meta/recipes-kernel/trace-cmd/trace-cmd_git.bb |    5 +++--
 1 files changed, 3 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb b/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb
index a7eca5f..bc03b0c 100644
--- a/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb
+++ b/meta/recipes-kernel/trace-cmd/trace-cmd_git.bb
@@ -1,6 +1,7 @@
 DESCRIPTION = "User interface to Ftrace"
-LICENSE = "GPL"
-LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://trace-cmd.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e"
 
 PR = r2
 PV = "1.0.4+git${SRCPV}"
-- 
1.7.1



^ permalink raw reply related	[flat|nested] 10+ messages in thread

* [PATCH 0/4 V2] tracing: trace-cmd fixes and new kernelshark recipe
@ 2011-01-03 17:46 Darren Hart
  2010-12-29  1:10 ` [PATCH 4/4] kernelshark: add ftrace gui viewer Darren Hart
                   ` (3 more replies)
  0 siblings, 4 replies; 10+ messages in thread
From: Darren Hart @ 2011-01-03 17:46 UTC (permalink / raw)
  To: poky, sgw

This series fixes some issues with the existing trace-cmd recipe and adds
a new recipe for kernelshark. The latter catches a bug in glib-2.0 which
is also addressed in this series with a patch from Open Embedded.

V2: Update license and license files for trace-cmd and kernelshark

Pull URL: git://git.pokylinux.org/poky-contrib.git
  Branch: dvhart/tracing
  Browse: http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=dvhart/tracing

Thanks,
    Darren Hart <dvhart@linux.intel.com>
---


Darren Hart (4):
  trace-cmd: fix cross-compilation
  trace-cmd: license file updates
  glib-2.0: fix g_once_init_enter compile failure
  kernelshark: add ftrace gui viewer

 .../glib-2.0-2.27.3/g_once_init_enter.patch        |   13 +++++++++++
 meta/recipes-core/glib-2.0/glib-2.0_2.27.3.bb      |    6 +++-
 meta/recipes-kernel/trace-cmd/kernelshark_git.bb   |   22 ++++++++++++++++++++
 meta/recipes-kernel/trace-cmd/trace-cmd_git.bb     |   17 +++++++--------
 4 files changed, 47 insertions(+), 11 deletions(-)
 create mode 100644 meta/recipes-core/glib-2.0/glib-2.0-2.27.3/g_once_init_enter.patch
 create mode 100644 meta/recipes-kernel/trace-cmd/kernelshark_git.bb



^ permalink raw reply	[flat|nested] 10+ messages in thread

* Re: [PATCH 4/4] kernelshark: add ftrace gui viewer
  2010-12-29  1:10 ` [PATCH 4/4] kernelshark: add ftrace gui viewer Darren Hart
@ 2011-01-03 19:04   ` Richard Purdie
  2011-01-03 19:23     ` Darren Hart
  2011-01-03 19:06   ` Darren Hart
  1 sibling, 1 reply; 10+ messages in thread
From: Richard Purdie @ 2011-01-03 19:04 UTC (permalink / raw)
  To: Darren Hart; +Cc: poky

On Tue, 2010-12-28 at 17:10 -0800, Darren Hart wrote:
> trace-cmd/kernelshark_git.bb b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
> new file mode 100644
> index 0000000..781f983
> --- /dev/null
> +++ b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
> @@ -0,0 +1,22 @@
> +DESCRIPTION = "Graphical trace viewer for Ftrace"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
> +                    file://kernelshark.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e"
> +
> +PR = r0
> +PV = "1.0.4+git${SRCPV}"
> +
> +DEPENDS = "gtk+"
> +RDEPENDS = "trace-cmd"

This should be RDEPENDS_${PN} I suspect. We need to be clear about which
package has the runtime dependency.

> +inherit pkgconfig
> +
> +SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/rostedt/trace-cmd.git;protocol=git"
> +SRCREV = "${SRCREV_pn-trace-cmd}"

I'd suggest declaring that alongside the trace-cmd SRCREV definition,
something like:

TRACECMDREV ?= "xxx"
SRCREV_pn-trace-cmd ?= "${TRACECMDREV}"
SRCREV_pn-kernelshark ?= "${TRACECMDREV}"

> +S = "${WORKDIR}/git"
> +
> +EXTRA_OEMAKE = "'CC=${CC}' 'AR=${AR}' 'prefix=${prefix}' gui"
> +
> +do_install() {
> +	oe_runmake CC="${CC}" AR="${AR}" prefix="${prefix}" DESTDIR="${D}" install_gui
> +}

Cheers,

Richard




^ permalink raw reply	[flat|nested] 10+ messages in thread

* Re: [PATCH 4/4] kernelshark: add ftrace gui viewer
  2010-12-29  1:10 ` [PATCH 4/4] kernelshark: add ftrace gui viewer Darren Hart
  2011-01-03 19:04   ` Richard Purdie
@ 2011-01-03 19:06   ` Darren Hart
  1 sibling, 0 replies; 10+ messages in thread
From: Darren Hart @ 2011-01-03 19:06 UTC (permalink / raw)
  To: Darren Hart; +Cc: poky

On 12/28/2010 05:10 PM, Darren Hart wrote:
> The trace-cmd source includes a graphical trace viewer, but we
> don't want to make the trace-cmd recipe depend on gtk+. This
> patch adds a second recipe in the meta/recipes-kernel/trace-cmd
> directory which uses the trace-cmd SRCREV and RDEPENDS on trace-cmd
> to ensure compatibility.
>
> Signed-off-by: Darren Hart<dvhart@linux.intel.com>
> CC: Tom Zanussi<tom.zanussi@intel.com>
> ---
>   meta/recipes-kernel/trace-cmd/kernelshark_git.bb |   22 ++++++++++++++++++++++
>   1 files changed, 22 insertions(+), 0 deletions(-)
>   create mode 100644 meta/recipes-kernel/trace-cmd/kernelshark_git.bb
>
> diff --git a/meta/recipes-kernel/trace-cmd/kernelshark_git.bb b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
> new file mode 100644
> index 0000000..781f983
> --- /dev/null
> +++ b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
> @@ -0,0 +1,22 @@
> +DESCRIPTION = "Graphical trace viewer for Ftrace"
> +LICENSE = "GPLv2"
> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
> +                    file://kernelshark.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e"

This should have been kernel-shark.c. A failed thermal cleaning of the 
previous build resulted in my not catching it. I have fixed this in my 
contrib branch, but won't resend the patch series unless requested.

-- 
Darren Hart



^ permalink raw reply	[flat|nested] 10+ messages in thread

* Re: [PATCH 4/4] kernelshark: add ftrace gui viewer
  2011-01-03 19:04   ` Richard Purdie
@ 2011-01-03 19:23     ` Darren Hart
  2011-01-03 19:31       ` Koen Kooi
  2011-01-03 19:36       ` Richard Purdie
  0 siblings, 2 replies; 10+ messages in thread
From: Darren Hart @ 2011-01-03 19:23 UTC (permalink / raw)
  To: Richard Purdie; +Cc: poky

On 01/03/2011 11:04 AM, Richard Purdie wrote:
> On Tue, 2010-12-28 at 17:10 -0800, Darren Hart wrote:
>> trace-cmd/kernelshark_git.bb b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
>> new file mode 100644
>> index 0000000..781f983
>> --- /dev/null
>> +++ b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
>> @@ -0,0 +1,22 @@
>> +DESCRIPTION = "Graphical trace viewer for Ftrace"
>> +LICENSE = "GPLv2"
>> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
>> +                    file://kernelshark.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e"
>> +
>> +PR = r0
>> +PV = "1.0.4+git${SRCPV}"
>> +
>> +DEPENDS = "gtk+"
>> +RDEPENDS = "trace-cmd"
>
> This should be RDEPENDS_${PN} I suspect. We need to be clear about which
> package has the runtime dependency.

Hi Richard, thanks for the review.

I'm missing something about how these variables are used I guess. I had 
thought that being assigned inside the kernelshark_git.bb recipe would 
have been sufficient to make it clear it applied to kernelshark. How 
does this bleed over into other recipes?

>
>> +inherit pkgconfig
>> +
>> +SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/rostedt/trace-cmd.git;protocol=git"
>> +SRCREV = "${SRCREV_pn-trace-cmd}"
>
> I'd suggest declaring that alongside the trace-cmd SRCREV definition,
> something like:
>
> TRACECMDREV ?= "xxx"
> SRCREV_pn-trace-cmd ?= "${TRACECMDREV}"
> SRCREV_pn-kernelshark ?= "${TRACECMDREV}"

If I do this, I think a trace-cmd.inc would be the right way to go. 
Having kernelshark specific bits in the base trace-cmd recipe seems 
backwards to me: kernelshark builds on trace-cmd, so it makes sense to 
me for the extension to made in the kernelshark recipe.

-- 
Darren Hart
Yocto Linux Kernel


^ permalink raw reply	[flat|nested] 10+ messages in thread

* Re: [PATCH 4/4] kernelshark: add ftrace gui viewer
  2011-01-03 19:23     ` Darren Hart
@ 2011-01-03 19:31       ` Koen Kooi
  2011-01-03 19:36       ` Richard Purdie
  1 sibling, 0 replies; 10+ messages in thread
From: Koen Kooi @ 2011-01-03 19:31 UTC (permalink / raw)
  To: poky


Op 3 jan 2011, om 20:23 heeft Darren Hart het volgende geschreven:

> On 01/03/2011 11:04 AM, Richard Purdie wrote:
>> On Tue, 2010-12-28 at 17:10 -0800, Darren Hart wrote:
>>> 
>>> +DEPENDS = "gtk+"
>>> +RDEPENDS = "trace-cmd"
>> 
>> This should be RDEPENDS_${PN} I suspect. We need to be clear about which
>> package has the runtime dependency.
> 
> Hi Richard, thanks for the review.
> 
> I'm missing something about how these variables are used I guess. I had thought that being assigned inside the kernelshark_git.bb recipe would have been sufficient to make it clear it applied to kernelshark. How does this bleed over into other recipes?

It bleeds over into the -dev, -dbg and any other packages the recipes generates.

regards,

Koen

^ permalink raw reply	[flat|nested] 10+ messages in thread

* Re: [PATCH 4/4] kernelshark: add ftrace gui viewer
  2011-01-03 19:23     ` Darren Hart
  2011-01-03 19:31       ` Koen Kooi
@ 2011-01-03 19:36       ` Richard Purdie
  1 sibling, 0 replies; 10+ messages in thread
From: Richard Purdie @ 2011-01-03 19:36 UTC (permalink / raw)
  To: Darren Hart; +Cc: poky

On Mon, 2011-01-03 at 11:23 -0800, Darren Hart wrote:
> On 01/03/2011 11:04 AM, Richard Purdie wrote:
> > On Tue, 2010-12-28 at 17:10 -0800, Darren Hart wrote:
> >> trace-cmd/kernelshark_git.bb b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
> >> new file mode 100644
> >> index 0000000..781f983
> >> --- /dev/null
> >> +++ b/meta/recipes-kernel/trace-cmd/kernelshark_git.bb
> >> @@ -0,0 +1,22 @@
> >> +DESCRIPTION = "Graphical trace viewer for Ftrace"
> >> +LICENSE = "GPLv2"
> >> +LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
> >> +                    file://kernelshark.c;beginline=6;endline=8;md5=2c22c965a649ddd7973d7913c5634a5e"
> >> +
> >> +PR = r0
> >> +PV = "1.0.4+git${SRCPV}"
> >> +
> >> +DEPENDS = "gtk+"
> >> +RDEPENDS = "trace-cmd"
> >
> > This should be RDEPENDS_${PN} I suspect. We need to be clear about which
> > package has the runtime dependency.
> 
> Hi Richard, thanks for the review.
> 
> I'm missing something about how these variables are used I guess. I had 
> thought that being assigned inside the kernelshark_git.bb recipe would 
> have been sufficient to make it clear it applied to kernelshark. How 
> does this bleed over into other recipes?

Other packages (.rpm/ipk), not recipes.

RDEPENDS = "XXX" means apply this RDEPENDS to every package the
kernelshark recipe generates. This as standard would be:

kernelshark
kernelshark-dbg
kernelshark-dev
kernelshark-doc

and it clearly doesn't apply for the last three, only the first (in
general principle, the kernelshark recipe probably doesn't generate a
-doc at all but you get the idea).



> >> +inherit pkgconfig
> >> +
> >> +SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/rostedt/trace-cmd.git;protocol=git"
> >> +SRCREV = "${SRCREV_pn-trace-cmd}"
> >
> > I'd suggest declaring that alongside the trace-cmd SRCREV definition,
> > something like:
> >
> > TRACECMDREV ?= "xxx"
> > SRCREV_pn-trace-cmd ?= "${TRACECMDREV}"
> > SRCREV_pn-kernelshark ?= "${TRACECMDREV}"
> 
> If I do this, I think a trace-cmd.inc would be the right way to go. 
> Having kernelshark specific bits in the base trace-cmd recipe seems 
> backwards to me: kernelshark builds on trace-cmd, so it makes sense to 
> me for the extension to made in the kernelshark recipe.

I meant in the common .inc file in the distro directiory where all the
other SRCREVs are set.

Cheers,

Richard




^ permalink raw reply	[flat|nested] 10+ messages in thread

end of thread, other threads:[~2011-01-03 19:36 UTC | newest]

Thread overview: 10+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2011-01-03 17:46 [PATCH 0/4 V2] tracing: trace-cmd fixes and new kernelshark recipe Darren Hart
2010-12-29  1:10 ` [PATCH 4/4] kernelshark: add ftrace gui viewer Darren Hart
2011-01-03 19:04   ` Richard Purdie
2011-01-03 19:23     ` Darren Hart
2011-01-03 19:31       ` Koen Kooi
2011-01-03 19:36       ` Richard Purdie
2011-01-03 19:06   ` Darren Hart
2010-12-29  1:17 ` [PATCH 1/4] trace-cmd: fix cross-compilation Darren Hart
2010-12-29 18:10 ` [PATCH 3/4] glib-2.0: fix g_once_init_enter compile failure Darren Hart
2011-01-03 17:39 ` [PATCH 2/4] trace-cmd: license file updates Darren Hart

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox