[PATCH 0/2] Split IMAGE* variables into a separate class

[PATCH 0/2] Split IMAGE* variables into a separate class

[Richard Purdie]

From: Richard Purdie <richard.purdie@linuxfoundation.org>

These patches split the IMAGE* variables out into a separate class
to improve readabilty. The patch descriptions themselves have the details.

Pull URL: git://git.openembedded.org/openembedded-core-contrib
  Branch: rpurdie/imagetypes
  Browse: http://git.openembedded.org/cgit.cgi/openembedded-core-contrib/log/?h=rpurdie/imagetypes

Thanks,
    Richard Purdie <richard.purdie@linuxfoundation.org>
---


Richard Purdie (2):
  bitbake.conf/image.bbclass: Move image type information into
    image_types.bbclass
  image_types.bbclass: Drop IMAGE_EXTRA_OPTION in favour of the more
    standard EXTRA_IMAGECMD

 meta/classes/image.bbclass       |   22 +---------
 meta/classes/image_types.bbclass |   86 ++++++++++++++++++++++++++++++++++++++
 meta/conf/bitbake.conf           |   44 -------------------
 3 files changed, 87 insertions(+), 65 deletions(-)
 create mode 100644 meta/classes/image_types.bbclass

-- 
1.7.4.1

[PATCH 1/2] bitbake.conf/image.bbclass: Move image type information into image_types.bbclass

[Richard Purdie]

From: Richard Purdie <richard.purdie@linuxfoundation.org>

Image generation code in .conf files is hard to read as it needs to be
single line. By moving this to a separate class, multiline functions
can be used instead improving readability. It also declutters
bitbake.conf.

There is no real functional change with this patch but it highlights
the need for improvements in places such as the IMAGE_EXTRA_OPTION
ext* specific variable which makes no sense.

Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
---
 meta/classes/image.bbclass       |   22 +----------
 meta/classes/image_types.bbclass |   81 ++++++++++++++++++++++++++++++++++++++
 meta/conf/bitbake.conf           |   41 -------------------
 3 files changed, 82 insertions(+), 62 deletions(-)
 create mode 100644 meta/classes/image_types.bbclass

diff --git a/meta/classes/image.bbclass b/meta/classes/image.bbclass
index eb0d970..aa842c7 100644
--- a/meta/classes/image.bbclass
+++ b/meta/classes/image.bbclass
@@ -64,27 +64,7 @@ def get_devtable_list(d):
         str += " %s" % bb.which(bb.data.getVar('BBPATH', d, 1), devtable)
     return str
 
-def get_imagecmds(d):
-    cmds = "\n"
-    old_overrides = bb.data.getVar('OVERRIDES', d, 0)
-    for type in bb.data.getVar('IMAGE_FSTYPES', d, True).split():
-        localdata = bb.data.createCopy(d)
-        localdata.setVar('OVERRIDES', '%s:%s' % (type, old_overrides))
-        bb.data.update_data(localdata)
-        localdata.setVar('type', type)
-        cmd = localdata.getVar("IMAGE_CMD_" + type, True)
-        localdata.setVar('cmd', cmd)
-        cmds += localdata.getVar("runimagecmd", True)
-    return cmds
-
-runimagecmd () {
-	# Image generation code for image type ${type}
-	ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = $1 * ${IMAGE_OVERHEAD_FACTOR}; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
-	${cmd}
-	cd ${DEPLOY_DIR_IMAGE}/
-	rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
-	ln -s ${IMAGE_NAME}.rootfs.${type} ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
-}
+inherit image_types
 
 IMAGE_POSTPROCESS_COMMAND ?= ""
 MACHINE_POSTPROCESS_COMMAND ?= ""
diff --git a/meta/classes/image_types.bbclass b/meta/classes/image_types.bbclass
new file mode 100644
index 0000000..5c9bcd1
--- /dev/null
+++ b/meta/classes/image_types.bbclass
@@ -0,0 +1,81 @@
+def get_imagecmds(d):
+    cmds = "\n"
+    old_overrides = bb.data.getVar('OVERRIDES', d, 0)
+    for type in bb.data.getVar('IMAGE_FSTYPES', d, True).split():
+        localdata = bb.data.createCopy(d)
+        localdata.setVar('OVERRIDES', '%s:%s' % (type, old_overrides))
+        bb.data.update_data(localdata)
+        localdata.setVar('type', type)
+        cmd = localdata.getVar("IMAGE_CMD_" + type, True)
+        localdata.setVar('cmd', cmd)
+        cmds += localdata.getVar("runimagecmd", True)
+    return cmds
+
+runimagecmd () {
+	# Image generation code for image type ${type}
+	ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = $1 * ${IMAGE_OVERHEAD_FACTOR}; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
+	${cmd}
+	cd ${DEPLOY_DIR_IMAGE}/
+	rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
+	ln -s ${IMAGE_NAME}.rootfs.${type} ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
+}
+
+IMAGE_CMD_jffs2 = "mkfs.jffs2 --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
+IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
+IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
+IMAGE_CMD_ext2 = "genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
+IMAGE_CMD_ext2.gz () {
+	rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz
+	genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}
+	gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2
+	mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz
+	rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz
+}
+IMAGE_CMD_ext3 () {
+	genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}
+	tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3
+}
+IMAGE_CMD_ext3.gz () {
+	rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz
+	genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}
+	tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3
+	gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3
+	mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz
+	rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz
+}
+IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
+IMAGE_CMD_squashfs-lzma = "mksquashfs-lzma ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend"
+IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
+IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
+IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
+IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio)"
+IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz)"
+IMAGE_CMD_ubi () {
+	echo \[ubifs\] > ubinize.cfg 
+	echo mode=ubi >> ubinize.cfg
+	echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg 
+	echo vol_id=0 >> ubinize.cfg 
+	echo vol_type=dynamic >> ubinize.cfg 
+	echo vol_name=${UBI_VOLNAME} >> ubinize.cfg 
+	echo vol_flags=autoresize >> ubinize.cfg
+	mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg
+}
+IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
+
+EXTRA_IMAGECMD = ""
+EXTRA_IMAGECMD_jffs2 = "--pad --little-endian --eraseblock=0x40000"
+EXTRA_IMAGECMD_yaffs2 = "1"
+
+IMAGE_DEPENDS = ""
+IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
+IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
+IMAGE_DEPENDS_cramfs = "cramfs-native"
+IMAGE_DEPENDS_ext2 = "genext2fs-native"
+IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
+IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
+IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
+IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
+IMAGE_DEPENDS_squashfs-lzma = "squashfs-lzma-tools-native"
+IMAGE_DEPENDS_ubi = "mtd-utils-native"
+IMAGE_DEPENDS_ubifs = "mtd-utils-native"
+
diff --git a/meta/conf/bitbake.conf b/meta/conf/bitbake.conf
index 22532db..8e89945 100644
--- a/meta/conf/bitbake.conf
+++ b/meta/conf/bitbake.conf
@@ -355,47 +355,6 @@ IMAGE_OVERHEAD_FACTOR ?= 1.3
 # Comment this option if you want default genext2fs behavior (i.e. create minimal inode number)
 IMAGE_EXTRA_OPTION ?= "-i 8192"
 
-IMAGE_CMD = ""
-IMAGE_CMD_jffs2 = "mkfs.jffs2 --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
-IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
-IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
-IMAGE_CMD_ext2 = "genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
-IMAGE_CMD_ext2.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
-IMAGE_CMD_ext3 = "genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
-IMAGE_CMD_ext3.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
-IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
-IMAGE_CMD_squashfs-lzma = "mksquashfs-lzma ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend"
-IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
-IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
-IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
-IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio)"
-IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz)"
-IMAGE_CMD_ubi = "echo \[ubifs\] > ubinize.cfg ; echo mode=ubi >> ubinize.cfg ; echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg ; echo vol_id=0 >> ubinize.cfg ; echo vol_type=dynamic >> ubinize.cfg ; echo vol_name=${UBI_VOLNAME} >> ubinize.cfg ; echo vol_flags=autoresize >> ubinize.cfg;mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg"
-IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
-
-EXTRA_IMAGECMD = ""
-EXTRA_IMAGECMD_jffs2 = "--pad --little-endian --eraseblock=0x40000"
-EXTRA_IMAGECMD_yaffs2 = "1"
-EXTRA_IMAGECMD_squashfs = ""
-EXTRA_IMAGECMD_squashfs-lzma = ""
-EXTRA_IMAGECMD_cpio = ""
-EXTRA_IMAGECMD_cpio.gz = ""
-EXTRA_IMAGECMD_ubi = ""
-EXTRA_IMAGECMD_ubifs = ""
-
-IMAGE_DEPENDS = ""
-IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
-IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
-IMAGE_DEPENDS_cramfs = "cramfs-native"
-IMAGE_DEPENDS_ext2 = "genext2fs-native"
-IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
-IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
-IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
-IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
-IMAGE_DEPENDS_squashfs-lzma = "squashfs-lzma-tools-native"
-IMAGE_DEPENDS_ubi = "mtd-utils-native"
-IMAGE_DEPENDS_ubifs = "mtd-utils-native"
-
 EXTRA_IMAGEDEPENDS = ""
 
 ##################################################################
-- 
1.7.4.1

[PATCH 2/2] image_types.bbclass: Drop IMAGE_EXTRA_OPTION in favour of the more standard EXTRA_IMAGECMD

[Richard Purdie]

From: Richard Purdie <richard.purdie@linuxfoundation.org>

Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
---
 meta/classes/image_types.bbclass |   13 +++++++++----
 meta/conf/bitbake.conf           |    3 ---
 2 files changed, 9 insertions(+), 7 deletions(-)

diff --git a/meta/classes/image_types.bbclass b/meta/classes/image_types.bbclass
index 5c9bcd1..f11a7ed 100644
--- a/meta/classes/image_types.bbclass
+++ b/meta/classes/image_types.bbclass
@@ -23,21 +23,21 @@ runimagecmd () {
 IMAGE_CMD_jffs2 = "mkfs.jffs2 --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
-IMAGE_CMD_ext2 = "genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
+IMAGE_CMD_ext2 = "genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${EXTRA_IMAGECMD} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2"
 IMAGE_CMD_ext2.gz () {
 	rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz
-	genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}
+	genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${EXTRA_IMAGECMD} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2
 	gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2
 	mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz
 	rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz
 }
 IMAGE_CMD_ext3 () {
-	genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}
+	genext2fs -b $ROOTFS_SIZE -d ${IMAGE_ROOTFS} ${EXTRA_IMAGECMD} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3
 	tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3
 }
 IMAGE_CMD_ext3.gz () {
 	rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz
-	genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${IMAGE_EXTRA_OPTION} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}
+	genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${EXTRA_IMAGECMD} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3
 	tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3
 	gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3
 	mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz
@@ -65,6 +65,11 @@ IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_
 EXTRA_IMAGECMD = ""
 EXTRA_IMAGECMD_jffs2 = "--pad --little-endian --eraseblock=0x40000"
 EXTRA_IMAGECMD_yaffs2 = "1"
+# Change these if you want default genext2fs behavior (i.e. create minimal inode number)
+EXTRA_IMAGECMD_ext2 ?= "-i 8192"
+EXTRA_IMAGECMD_ext2.gz ?= "-i 8192"
+EXTRA_IMAGECMD_ext3 ?= "-i 8192"
+EXTRA_IMAGECMD_ext3.gz ?= "-i 8192"
 
 IMAGE_DEPENDS = ""
 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
diff --git a/meta/conf/bitbake.conf b/meta/conf/bitbake.conf
index 8e89945..6b6b2ee 100644
--- a/meta/conf/bitbake.conf
+++ b/meta/conf/bitbake.conf
@@ -352,9 +352,6 @@ IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 # fixed extra space
 IMAGE_OVERHEAD_FACTOR ?= 1.3
 
-# Comment this option if you want default genext2fs behavior (i.e. create minimal inode number)
-IMAGE_EXTRA_OPTION ?= "-i 8192"
-
 EXTRA_IMAGEDEPENDS = ""
 
 ##################################################################
-- 
1.7.4.1

Re: [PATCH 0/2] Split IMAGE* variables into a separate class

[Koen Kooi]

Op 24 mrt 2011, om 15:49 heeft Richard Purdie het volgende geschreven:

> From: Richard Purdie <richard.purdie@linuxfoundation.org>
> 
> These patches split the IMAGE* variables out into a separate class
> to improve readabilty. 

I like it!

Re: [PATCH 0/2] Split IMAGE* variables into a separate class

[Tom Rini]

On 03/24/2011 08:39 AM, Koen Kooi wrote:
>
> Op 24 mrt 2011, om 15:49 heeft Richard Purdie het volgende geschreven:
>
>> From: Richard Purdie<richard.purdie@linuxfoundation.org>
>>
>> These patches split the IMAGE* variables out into a separate class
>> to improve readabilty.
>
> I like it!

Agreed.  This will help us clean up the N instances of make an ext2 
image, modify.

-- 
Tom Rini
Mentor Graphics Corporation

Re: [PATCH 0/2] Split IMAGE* variables into a separate class

[Richard Purdie]

On Thu, 2011-03-24 at 14:49 +0000, Richard Purdie wrote:
> From: Richard Purdie <richard.purdie@linuxfoundation.org>
> 
> These patches split the IMAGE* variables out into a separate class
> to improve readabilty. The patch descriptions themselves have the details.
> 
> Pull URL: git://git.openembedded.org/openembedded-core-contrib
>   Branch: rpurdie/imagetypes
>   Browse: http://git.openembedded.org/cgit.cgi/openembedded-core-contrib/log/?h=rpurdie/imagetypes
> 
> Thanks,
>     Richard Purdie <richard.purdie@linuxfoundation.org>
> ---
> 
> 
> Richard Purdie (2):
>   bitbake.conf/image.bbclass: Move image type information into
>     image_types.bbclass
>   image_types.bbclass: Drop IMAGE_EXTRA_OPTION in favour of the more
>     standard EXTRA_IMAGECMD

I've merged these to master.

Cheers,

Richard

[PATCH 0/3] port oe-dev ,ubifs.img link support

[Ben Gardiner]

I made some changes in oe-dev to normalize the link names used for the 
ubifs images created when the type is ubifs vs. when the type is UBI. 
The changes we two-fold: make symlinks to either .rootfs.<type> or 
<type>.img and use the <type>.img extension for the ubifs images when 
they are intermediate for UBI image generation as well as the final 
target.

The changes were accepted by Tom Rini for oe-dev and Denys Dmytriyenko 
for arago.

I've only just begun following the oe-core list and I noticed your 
(Richard's) changes to introduce image_type.bbclass to oe-core. When I 
looked closer at the changes I could see that there had been no sync-up 
from oe-dev to oe-core since the changes I mentioned above.

This changeset should align oe-core with those recent changes in oe-dev; 
the changes I made were dependent on Bernhard's change to replace the 
symlink target with 'ln -f' instead of 'rm'ing it first; so I ported his 
commit also.

I'm sorry to say that there has been no testing of these changes with 
oe-core. I would be interested in trying a test build... but I must admit
I don't know what MACHINE+DISTRO+image to try as a simple test build.

Ben Gardiner (2):
  image_types.bbclass: add link to .rootfs.<type> or .<type>.img
  image_types.bbclass: use .ubifs.img extension in IMAGE_CMD_ubi

Bernhard Reutner-Fischer (1):
  image_types.bbclass: rm symlink destination via ln

 meta/classes/image_types.bbclass | 11 +++++++----
 1 files changed, 7 insertions(+), 4 deletions(-)

[PATCH 1/3] image_types.bbclass: rm symlink destination via ln

[Ben Gardiner]

From: Bernhard Reutner-Fischer <rep.dot.nop@gmail.com>

( This is a port of commit ffdf56431d26ce54377d672764a8bba61dcaf853
from git://git.openembedded.org/openembedded )

Rather than rm'ing the destination-file manually, do ln -f

Signed-off-by: Bernhard Reutner-Fischer <rep.dot.nop@gmail.com>
Acked-by: Roman I Khimov <khimov@altell.ru>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Ben Gardiner <bengardiner@nanometrics.ca>
---
 meta/classes/image_types.bbclass |    3 +--
 1 files changed, 1 insertions(+), 2 deletions(-)

diff --git a/meta/classes/image_types.bbclass b/meta/classes/image_types.bbclass
index f11a7ed..696e978 100644
--- a/meta/classes/image_types.bbclass
+++ b/meta/classes/image_types.bbclass
@@ -16,8 +16,7 @@ runimagecmd () {
 	ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = $1 * ${IMAGE_OVERHEAD_FACTOR}; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
 	${cmd}
 	cd ${DEPLOY_DIR_IMAGE}/
-	rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
-	ln -s ${IMAGE_NAME}.rootfs.${type} ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
+	ln -fs ${IMAGE_NAME}.rootfs.${type} ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
 }
 
 IMAGE_CMD_jffs2 = "mkfs.jffs2 --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
-- 
1.7.0.4

[PATCH 2/3] image_types.bbclass: add link to .rootfs.<type> or .<type>.img

[Ben Gardiner]

( This is a port of commit cfde49e8d0f1cf09d589910f1a342849db148519
from git://git.openembedded.org/openembedded )

The current image link-creation code will unconditionaly create a link
from .<type> pointing to the .rootfs.<type> output.

This is not compatible with the UBIFS images produced which have
.<type>.img extension since they are not considered to be valid rootfs
images when they are not included in a UBI container.

Check for existence of the link target .rootfs.<type> before creating the
link and fallback to a check for the .<type>.img target after that.

Signed-off-by: Ben Gardiner <bengardiner@nanometrics.ca>
Acked-by: Denys Dmytriyenko <denys@ti.com>
Signed-off-by: Tom Rini <tom_rini@mentor.com>
Signed-off-by: Ben Gardiner <bengardiner@nanometrics.ca>
---
 meta/classes/image_types.bbclass |    6 +++++-
 1 files changed, 5 insertions(+), 1 deletions(-)

diff --git a/meta/classes/image_types.bbclass b/meta/classes/image_types.bbclass
index 696e978..6a66d21 100644
--- a/meta/classes/image_types.bbclass
+++ b/meta/classes/image_types.bbclass
@@ -16,7 +16,11 @@ runimagecmd () {
 	ROOTFS_SIZE=`du -ks ${IMAGE_ROOTFS}|awk '{size = $1 * ${IMAGE_OVERHEAD_FACTOR}; print (size > ${IMAGE_ROOTFS_SIZE} ? size : ${IMAGE_ROOTFS_SIZE}) }'`
 	${cmd}
 	cd ${DEPLOY_DIR_IMAGE}/
-	ln -fs ${IMAGE_NAME}.rootfs.${type} ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
+	if [ -f ${IMAGE_NAME}.rootfs.${type} ]; then
+		ln -fs ${IMAGE_NAME}.rootfs.${type} ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
+	elif [ -f ${IMAGE_NAME}.${type}.img ]; then
+		ln -fs ${IMAGE_NAME}.${type}.img ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.${type}
+	fi
 }
 
 IMAGE_CMD_jffs2 = "mkfs.jffs2 --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
-- 
1.7.0.4

[PATCH 3/3] image_types.bbclass: use .ubifs.img extension in IMAGE_CMD_ubi

[Ben Gardiner]

( This is a port of 7308e68fc26cdbffa08d311a2319c8d1c3b2805f
from git://git.openembedded.org/openembedded )

The current IMAGE_CMD_ubi creates an interim image with a .rootfs.ubifs
extension.

The ubifs image created is not considered a valid rootfs without a UBI
container.

Change the filename of the iterim ubifs image used by IMAGE_CMD_ubi to
.ubifs.img to match the IMAGE_CMD_ubifs command.

Signed-off-by: Ben Gardiner <bengardiner@nanometrics.ca>
Acked-by: Denys Dmytriyenko <denys@ti.com>
Signed-off-by: Tom Rini <tom_rini@mentor.com>
Signed-off-by: Ben Gardiner <bengardiner@nanometrics.ca>
---
 meta/classes/image_types.bbclass |    4 ++--
 1 files changed, 2 insertions(+), 2 deletions(-)

diff --git a/meta/classes/image_types.bbclass b/meta/classes/image_types.bbclass
index 6a66d21..1bfe6fd 100644
--- a/meta/classes/image_types.bbclass
+++ b/meta/classes/image_types.bbclass
@@ -56,12 +56,12 @@ IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -
 IMAGE_CMD_ubi () {
 	echo \[ubifs\] > ubinize.cfg 
 	echo mode=ubi >> ubinize.cfg
-	echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs >> ubinize.cfg 
+	echo image=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img >> ubinize.cfg
 	echo vol_id=0 >> ubinize.cfg 
 	echo vol_type=dynamic >> ubinize.cfg 
 	echo vol_name=${UBI_VOLNAME} >> ubinize.cfg 
 	echo vol_flags=autoresize >> ubinize.cfg
-	mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubifs ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg
+	mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS} && ubinize -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ubi ${UBINIZE_ARGS} ubinize.cfg
 }
 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img ${MKUBIFS_ARGS}"
 
-- 
1.7.0.4

Re: [PATCH 0/3] port oe-dev ,ubifs.img link support

[Tom Rini]

On 03/30/2011 09:36 PM, Ben Gardiner wrote:
> I made some changes in oe-dev to normalize the link names used for the 
> ubifs images created when the type is ubifs vs. when the type is UBI. 
> The changes we two-fold: make symlinks to either .rootfs.<type> or 
> <type>.img and use the <type>.img extension for the ubifs images when 
> they are intermediate for UBI image generation as well as the final 
> target.
> 
> The changes were accepted by Tom Rini for oe-dev and Denys Dmytriyenko 
> for arago.
> 
> I've only just begun following the oe-core list and I noticed your 
> (Richard's) changes to introduce image_type.bbclass to oe-core. When I 
> looked closer at the changes I could see that there had been no sync-up 
> from oe-dev to oe-core since the changes I mentioned above.
> 
> This changeset should align oe-core with those recent changes in oe-dev; 
> the changes I made were dependent on Bernhard's change to replace the 
> symlink target with 'ln -f' instead of 'rm'ing it first; so I ported his 
> commit also.
> 
> I'm sorry to say that there has been no testing of these changes with 
> oe-core. I would be interested in trying a test build... but I must admit
> I don't know what MACHINE+DISTRO+image to try as a simple test build.
> 
> Ben Gardiner (2):
>   image_types.bbclass: add link to .rootfs.<type> or .<type>.img
>   image_types.bbclass: use .ubifs.img extension in IMAGE_CMD_ubi
> 
> Bernhard Reutner-Fischer (1):
>   image_types.bbclass: rm symlink destination via ln
> 
>  meta/classes/image_types.bbclass | 11 +++++++----
>  1 files changed, 7 insertions(+), 4 deletions(-)

Thanks for doing this.  The whole series looks good to me,
Acked-by: Tom Rini <tom_rini@mentor.com>

-- 
Tom Rini
Mentor Graphics Corporation

Re: [PATCH 0/3] port oe-dev ,ubifs.img link support

[Denys Dmytriyenko]

On Thu, Mar 31, 2011 at 12:36:35AM -0400, Ben Gardiner wrote:
> I made some changes in oe-dev to normalize the link names used for the 
> ubifs images created when the type is ubifs vs. when the type is UBI. 
> The changes we two-fold: make symlinks to either .rootfs.<type> or 
> <type>.img and use the <type>.img extension for the ubifs images when 
> they are intermediate for UBI image generation as well as the final 
> target.

Ben,

That seems like a good patchset for oe-core at this point. Especially in the 
light of Richard's proposal for image_types.bbclass...

Acked-by: Denys Dmytriyenko <denys@ti.com>


> The changes were accepted by Tom Rini for oe-dev and Denys Dmytriyenko 
> for arago.
> 
> I've only just begun following the oe-core list and I noticed your 
> (Richard's) changes to introduce image_type.bbclass to oe-core. When I 
> looked closer at the changes I could see that there had been no sync-up 
> from oe-dev to oe-core since the changes I mentioned above.
> 
> This changeset should align oe-core with those recent changes in oe-dev; 
> the changes I made were dependent on Bernhard's change to replace the 
> symlink target with 'ln -f' instead of 'rm'ing it first; so I ported his 
> commit also.
> 
> I'm sorry to say that there has been no testing of these changes with 
> oe-core. I would be interested in trying a test build... but I must admit
> I don't know what MACHINE+DISTRO+image to try as a simple test build.
> 
> Ben Gardiner (2):
>   image_types.bbclass: add link to .rootfs.<type> or .<type>.img
>   image_types.bbclass: use .ubifs.img extension in IMAGE_CMD_ubi
> 
> Bernhard Reutner-Fischer (1):
>   image_types.bbclass: rm symlink destination via ln
> 
>  meta/classes/image_types.bbclass | 11 +++++++----
>  1 files changed, 7 insertions(+), 4 deletions(-)
> 
> 
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core